turtles-own
[
  x-pos  ;; x-pos, y-pos, in z-pos so kartezične koordinate
  y-pos  ;; ne zamesaj z xcor in ycor, ki so vnaprej določene
  z-pos  ;;   NetLogo spremenljivka za točke
  p      ;; p, theta, in fi so sferične koordinate
  theta
  fi
 ]

to setup
  clear-all
  set-default-shape turtles "circle"
end

to sfera
  setup
  ;; generira sfero z radijem VELIKOST-TELESA
  crt stevilo-tock
  [
    set p velikost-telesa            ; vse točke so enako oddaljene od središča
    set theta random-float 360  ; naključna porazdelitev po površini sfere
    set fi random-float 180
    render-turtle
  ]
end

; polna 3D kocka
to polna-kocka
  setup
  ;; generira kocko z robom dolžine radija
  ;; točke postavi naključno kamorkoli v notranjost kocke
  crt stevilo-tock
  [
    cartesian ((- velikost-telesa) + 2 * (random-float velikost-telesa))
              ((- velikost-telesa) + 2 * (random-float velikost-telesa))
              ((- velikost-telesa) + 2 * (random-float velikost-telesa))
    render-turtle
  ]
end

; kocka s pikami samo na svoji površini
to povrsina-kocke
  setup
  crt stevilo-tock
  [
    let temp-alpha velikost-telesa * (1 - 2 * (random 2))   ; +-velikost-telesa
    ; naključna porazdelitev omejena z +-velikost-telesa
    let temp-beta velikost-telesa - 2 * (random-float velikost-telesa)
    let temp-gamma (random 2)                          ; sprednja/zadnja ali leva/desna?
    ifelse temp-gamma = 0                              ; generira sprednjo & zadnjo ploskev
    [
      cartesian (temp-alpha)
                (temp-beta)
                (velikost-telesa - (2 * (random-float velikost-telesa)))
    ]
    [
      cartesian (temp-beta)                             ; generira stranske ploskve
                (temp-alpha)
                (velikost-telesa - (2 * (random-float velikost-telesa)))
    ]
    render-turtle
  ]
end


; 3D stožec
to stozec
  setup
  crt stevilo-tock
  [
    set theta (random-float 360)        ; točke imajo nakljucen kot
    set p (random-float velikost-telesa)
    cartesian (p * (cos theta))     ; x = r*cos(theta)
              (p * (sin theta))     ; y = r*sin(theta)
              (velikost-telesa - 2 * p)  ; postavi originalni stožec v središče
                                   ; namesto da bi bil samo na pozitivni strani
    render-turtle
  ]
end

; valj, ko se vrti pokončno
to valj-pokoncno
  setup
  ;ta koda je skoraj enaka kot koda za stožec
  ;razlika je le, da radij xy-ravnine ostane konstanten
  crt stevilo-tock
  [
    let temp-alpha (random 3) - 1         ; katera ploskev (leva, desna ali telesna?)
    set theta (random-float 360)
    ifelse temp-alpha = 0
    [
      cartesian (velikost-telesa * (cos theta))
                (velikost-telesa * (sin theta))
                ((- velikost-telesa) + 2 * (random-float velikost-telesa))
    ]
    [
      cartesian ((random-float velikost-telesa) * (cos theta))
                ((random-float velikost-telesa) * (sin theta))
                (temp-alpha * velikost-telesa)
    ]
    render-turtle
  ]
end

; valj, ki se vrti ležeče
to valj-lezece
  setup
  ;generira valj v vodoravni legi z pokritimi konci
  crt stevilo-tock
  [
    let temp-alpha (random 3) - 1      ; katera ploskev (leva, desna ali telesna?)
    set theta (random-float 360)
    ifelse temp-alpha = 0              ; generira trenutni valj
    [
      cartesian ((- velikost-telesa) + 2 * (random-float velikost-telesa))
                (velikost-telesa * (cos theta))
                (velikost-telesa * (sin theta))
    ]
    [
      cartesian (temp-alpha * velikost-telesa)
                ((random-float velikost-telesa) * (cos theta))
                ((random-float velikost-telesa) * (sin theta))
    ]
    render-turtle
  ]
end

to piramida
  setup
  crt stevilo-tock
  [
    let temp-alpha (- velikost-telesa) + 2 * (random-float velikost-telesa)  ; z koordinata
    set theta (random 2)                         ; spredaj/zadaj ali stransko?
    let temp-beta (velikost-telesa - temp-alpha) / 2
    let temp-gamma -1 + 2 * (random 2)           ; levo/desno ali spredaj/zadaj (-1 ali 1)
    ifelse theta = 0
    [
      cartesian (temp-beta * temp-gamma)          ;  leva & desna površina
                ((- temp-beta) + 2 * (random-float temp-beta))
                (temp-alpha)
    ]
    [
      cartesian ((- temp-beta) + 2 * (random-float temp-beta)) ;  sprednja & zadnja površina
                (temp-beta * temp-gamma)
                (temp-alpha)
    ]
    render-turtle
  ]
end

;; pretvorba iz kartezičnih v sferične koordinate
to cartesian [x y z]
  set p sqrt((x ^ 2) + (y ^ 2) + (z ^ 2))
  set fi (atan sqrt((x ^ 2) + (y ^ 2)) z)
  set theta (atan y x)
end

to prikazi
  ; rotacija točk okoli osi z
  ask turtles
  [
    set theta (theta + kotna-hitrost) mod 360  ; povečevanje kota za simuliranje vrtenja
    render-turtle
  ]
  tick
end

to render-turtle
  calculate-turtle-position
  set-turtle-position
end

;; pretvorba iz sferičnih v kartezične koordinate
to calculate-turtle-position
  set y-pos p * (sin fi) * (sin theta)
  set x-pos p * (sin fi) * (cos theta)
  set z-pos p * (cos fi)
end

;; nastavitve pozicije in barve točk
to set-turtle-position
  ifelse pogled = "od-strani"                                     ; stranski pogled
  [
    setxy x-pos z-pos
    set color scale-color prikazna-barva y-pos (- velikost-telesa) velikost-telesa
  ]
  [
    ifelse pogled = "od-zgoraj"                                  ; pogled od zgoraj
    [
      setxy x-pos y-pos
      set color scale-color prikazna-barva z-pos (- velikost-telesa) velikost-telesa
    ]
    [
      setxy (p * (sin fi) * (cos theta))              ; pogled od spodaj
            (- (p * (sin fi) * (sin theta)))
      set color scale-color prikazna-barva (- z-pos) (- velikost-telesa) velikost-telesa
    ]
  ]
end


; *** NetLogo 4.0.4 Model obvestilo o Avtorskih pravicah ***
;
; Ta model je bil ustvarjen kot del projekta: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML). Ta projekt s hvaležnostjo priznava podporo
; National Science Foundation (Applications of Advanced Technologies
; Program) -- številka dovoljenja RED #9552950 in REC #9632612.
;
; Avtorske pravice 1998 od Uri Wilensky. Vse pravice pridržane.
;
; Dovoljenje za uporabo, spremembe ali distribucijo tega modela je zaradi tega odobreno,
; vendar le pod pogojem, da sta obe od sledečih zahtev izpolnjeni:
; a) Vsebovan je zaznamek o avtorskih pravicah.
; b) Brez dovoljenja Urija Wilenskyja ta model ne bo distribuiran v profitne namene.
; Kontaktirajte Urija Wilenskyja za pridobitev dovoljenja za distribucijo v
; profitne namene.
;
; Ta model je bil spreobrnjen v NetLogo kot del sledečih projektov:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING
; IN CLASSROOMS in/ali INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; Ta projekt s hvaležnostjo priznava podporo
; National Science Foundation (programa REPP & ROLE) --
; številka dovoljenja REC #9814682 in REC-0126227.
; Spreobrnjeno iz StarLogoT v NetLogo, 2001.
;
; Za sklicevanje na ta model v akademskih publikacijah, prosimo navedite:
; Wilensky, U. (1998).  NetLogo 3D Solids model.
; http://ccl.northwestern.edu/netlogo/models/3DSolids.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; V ostalih publikacijah, prosimo uporabite:
; Avtorske pravice 1998 Uri Wilensky. Vse pravice pridrzane.
; Oglejte si http://ccl.northwestern.edu/netlogo/models/3DSolids
; za pogoje uporabe.
;
; *** konec NetLogo 4.0.4 Model obvestila o Avtorskih pravicah ***
@#$#@#$#@
GRAPHICS-WINDOW
298
10
671
404
60
60
3.0
1
10
1
1
1
0
0
0
1
-60
60
-60
60
1
1
1
poteze

CC-WINDOW
5
418
680
513
Command Center
0

BUTTON
176
38
269
71
prikazi
prikazi
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
158
136
288
169
stevilo-tock
stevilo-tock
0
2000
2000
1
1
NIL
HORIZONTAL

SLIDER
158
232
288
265
kotna-hitrost
kotna-hitrost
-10.0
10.0
1
1.0
1
NIL
HORIZONTAL

BUTTON
19
40
118
73
sfera
sfera
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
19
280
136
313
polna-kocka
polna-kocka
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
158
184
288
217
velikost-telesa
velikost-telesa
10.0
40.0
38.4
0.1
1
NIL
HORIZONTAL

BUTTON
19
88
118
121
stozec
stozec
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
19
136
136
169
valj-pokoncno
valj-pokoncno
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
19
184
134
217
valj-lezece
valj-lezece
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
19
232
150
265
povrsina-kocke
povrsina-kocke
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
19
328
118
361
piramida
piramida
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
158
88
288
121
prikazna-barva
prikazna-barva
5.0
135.0
25
10.0
1
NIL
HORIZONTAL

CHOOSER
200
358
292
403
pogled
pogled
"od-strani" "od-zgoraj" "od-spodaj"
0

@#$#@#$#@
KAJ JE TO?
-----------
Ta model ustvarja 3D telesa iz 2D točk, ki jih umešča med kartezične in sferične tridimenzionalne koordinate.


KAKO DELUJE?
------------
Za prikazovanje 3D teles program naključno razporeja točke na površini telesa (ali znotraj nje) v kartezičnih (x, y, z) ali sferičnih (theta, fi, z) koordinatah, odvisno v katerih je to enostavnejše, vendar pa informacija o sferičnih koordinatah, ko je ta obvezna, vedno ostane shranjena. Za prikaz sfere v NetLogovem pogledu, model pretvarja točkine sferične koordinate v kartezične, saj tako lahko z odtenki barv simulira globino. Položaji točk pa so vedno shranjeni v sferičnih koordinatah, saj je najenostavnejši način za izvedbo vrtenja okoli osi z povečevanje spremenljivke theta v sferičnih koordinatah.

Pretvarjanje iz kartezičnih v sferične koordinate:

x = r * cos(theta) = p * sin(fi) * cos(theta)
y = r * sin(theta) = p * sin(fi) * sin(theta)
z = p * cos(theta)

theta:  kot med točko in njeno projekcijo na ravnino xy.
fi: vpadni kot točke okoli osi z.
p: oddaljenost točke od izhodišča.


KAKO GA UPORABLJATI?
-------------
Kliknite gumbe z različnimi imeni teles; tako boste generirali animacije teh teles. Točke so naključno porazdeljene po površini ali po notranjosti telesa. Za zagon animacije kliknite gumb prikaži.

Gumb PRIKAŽI zažene animacijo (vrtenje) modela.

Gumb PRIKAZNA-BARVA določa barvo, ki bo uporabljena za simulacijo globine z generiranjem različnih odtenkov (v uporabi so vnaprej določene NetLogove barve).

Gumb STEVILO-TOCK določa število točk, ki bodo uporabljene za generiranje izbranega telesa.

Gumb VELIKOST-TELESA določa celotno velikost telesa. Najpogosteje s tem določimo dolžino radija ali stranice.

Gumb KOTNA-HITROST določa hitrost, s katero se točke vrtijo okoli določene osi.

(Vrtenje točk je realizirano preprosto z naraščanjem spremenljivke theta za vsako točko posebej z ukazom kotna-hitrost! VRTENJE točk (okoli njihove osi z) je enostavno v sferičnih koordinatah.  Vendar pa je po drugi strani transponiranje točk mnogo enostavnješe v kartezičnih koordinatah.)


STVARI, NA KATERE BODITE POZORNI
----------------
Opazite, da se bližnje točke (pozitivne) na osi y pojavljajo v svetlejšem odtenku, bolj oddaljene točke (negativne) pa se pojavljajo v temnejšem odtenku.


KAJ LAHKO POSKUSITE
-------------
Poskusite prilagajati kotno hitrost ter prikazne barve medtem, ko je model zagnan. Zagotovljen je takojšen odziv na vaše vnešene spremembe.


RAZŠIRITVE MODELA
-------------------
[PREPROSTO] Prilagodite postopek za generiranje kvadrata tako, da boste generirali pravokotnik.

Napišite postopek za zamenjavo (transponiranje) koordinat vsake točke. Vedite, da je to enostavneje v kartezičnih koordinatah.

Zapišite postopek za generiranje novih 3D geometrijskih objektov.

Poskusite animirati spremembe spremenljivke fi. Razmislite, zakaj to pravzaprav nima pravega smisla?

Zapišite postopek za rotacijo geometrijskih teles okoli različnih osi.

[ZELO TEŽKO] Zapišite psotopek za pogled na geometrijski telo iz POLJUBNEGA kota namesto le obstoječih treh.


NETLOGO POSEBNOSTI
----------------
Bodite pozorni na uporabo prikaznih barv za ponazoritev globine točk in s tem simulacijo 3D.


ZAUPNOST IN SKLICEVANJE
----------------------
Za sklicevanje na ta model v akademskih publikacijah, prosimo navedite:  Wilensky, U. (1998).  NetLogo 3D Solids model.  http://ccl.northwestern.edu/netlogo/models/3DSolids.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

V ostalih publikacijah, prosimo uporabite:  Avtorske pravice 1998 Uri Wilensky. Vse pravice pridrzane. Oglejte si http://ccl.northwestern.edu/netlogo/models/3DSolids za pogoje uporabe.

Prevod v slovenščino: Tilen Šetina
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.4
@#$#@#$#@
setup-sphere
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

@#$#@#$#@