globals [
  nebo-vrh      ;; y koordinata zgornje vrstice neba
  zemlja-vrh    ;; y koordinata zgornje vrstice Zemlje
  temperatura   ;; skupna temperatura
]

breed [zarki zarek]      ;; paketi soncne svetlobe
breed [IRi IR]           ;; paketi infrardecega sevanja
breed [toplote toplota]  ;; paketi toplotne energije
breed [CO2i CO2]         ;; paketi ogljikovega dioksida

breed [oblaki oblak]
oblaki-own [oblak-hitrost oblak-id]

;;
;; Procedure za nastavitev
;;

to nastavi
  clear-all
  set-default-shape zarki "ray"
  set-default-shape IRi "ray"
  set-default-shape oblaki "cloud"
  set-default-shape toplote "dot"
  set-default-shape CO2i "CO2-molecule"
  nastavi-svet
  set temperatura 12
  plot temperatura
end

to nastavi-svet
  set nebo-vrh max-pycor - 5
  set zemlja-vrh 0
  ask patches [  ;; nastavi barve za razlicne dele sveta
    if pycor > nebo-vrh [  ;; vesolje
      set pcolor scale-color white pycor 22 15
    ]
    if pycor <= nebo-vrh and pycor > zemlja-vrh [ ;; nebo
      set pcolor scale-color blue pycor -20 20
    ]
    if pycor < zemlja-vrh
      [ set pcolor red + 3 ] ;; Zemlja
    if pycor = zemlja-vrh ;; Zemljino povrsje
      [ update-albedo ]
  ]
end

;;
;; Procedure za potek
;;

to zacni
  ask oblaki [ fd oblak-hitrost ]  ;; premika oblake
  pozeni-sonce   ;; korak Sonce
  ;; ce se je drsnik albedo premaknil, posodobi barvo Zemljinega povrsja
  ask patches with [pycor = zemlja-vrh]
    [ update-albedo ]
  pozeni-toplota  ;; korak toplota
  pozeni-IR    ;; korak IR
  pozeni-CO2   ;; premika CO2 molekule
  tick
  plot temperatura
end

to update-albedo ;; procedura za podrocje
  set pcolor scale-color green albedo 0 1
end

to dodaj-oblak            ;; zbrise oblake in ustvari nove, plus se enega
  let nebo-visina nebo-vrh - zemlja-vrh
  ;; najde nakljucno visino za oblake,
  ;; vendar na nebu
  let y zemlja-vrh + (random-float (nebo-visina - 4)) + 2
  ;; noben oblak nima hitrosti 0
  let hitrost (random-float 0.1) + 0.01
  let x random-xcor
  let id 0
  ;; ni vazno, kaksen id ima oblak,
  ;; dokler imajo vse zelvice v oblaku
  ;; isti id in je ta edini med skupinami oblakov
  if any? oblaki
  [ set id max [oblak-id] of oblaki + 1 ]

  create-oblaki 3 + random 20
  [
    set oblak-hitrost hitrost
    set oblak-id id
    ;; vse zelvice v oblaku v vsakem vecjem oblaku
    ;; bi morale biti blizje, a ne neposredno nad drugimi,
    ;; zato dodamo malo prostora za vijuganje v x in y-smeri
    setxy x + random 9 - 4
          ;; oblaki bi morali biti na splosno zbrani okrog
          ;; sredisca z obcasnimi vecjimi odstopanji
          y + random-normal 2.5 1
    set color white
    ;; spreminanje velikosti je tudi le za vizualizacijo,
    ;; saj delamo zdruzenja le na podlagi podrocij
    set size 2 + random 2
    set heading 90
  ]
end

to odstrani-oblak       ;; izbrise oblake in ustvari nove, enega manj
  if any? oblaki [
    let odstranjen-id one-of remove-duplicates [oblak-id] of oblaki
    ask oblaki with [oblak-id = odstranjen-id]
      [ die ]
  ]
end

to pozeni-sonce
  ask zarki [
    if not can-move? 0.3 [ die ]  ;; na robu so zarki odstranjeni
    fd 0.3                        ;; sicer se se naprej gibljejo
  ]
  ustvari-sonce  ;; zacni posiljati nove zarke z vrha
  odbij-zarki-od-oblaki  ;; preveri, ce oblaki odbijajo zarke
  trk-zemlja   ;; preveri, ce Zemlja zarke absorbira ali jih odbija
end

to ustvari-sonce
  ;; ni nujno, da se vsakokrat ustvari zarek
  ;; ko se svetloba povecuje, ustvarimo vec zarkov
  if 10 * sonce-svetloba > random 50 [
    create-zarki 1 [
      set heading 160
      set color yellow
      ;; zarki prihajajo le iz majhnega podrocja
      ;; blizu vrha sveta
      setxy (random 10) + min-pxcor max-pycor
    ]
  ]
end

to odbij-zarki-od-oblaki
 ask zarki with [any? oblaki-here] [   ;; ce je zarek na istem podrocju kot oblak
   set heading 180 - heading   ;; se zarek obrne
 ]
end

to trk-zemlja
  ask zarki with [ycor <= zemlja-vrh] [
    ;; od albeda je odvisno, ali
    ;; Zemlja absorbira ali odbije toploto
    ifelse 100 * albedo > random 100
      [ set heading 180 - heading  ] ;; odbije
      [ rt random 45 - random 45 ;; absorbira v Zemljo
        set color red - 2 + random 4
        set breed toplote ]
  ]
end

to pozeni-toplota    ;; pospesi zelvice za toplotno energijo
  ;; temperatura je povezana s stevilom zelvic za toplotno energijo
  set temperatura 0.99 * temperatura + 0.01 * (12 + 0.1 * count toplote)
  ask toplote
  [
    let razdalja 0.5 * random-float 1
    ifelse can-move? razdalja
      [ fd razdalja ]
      [ set heading 180 - heading ] ;; ce se zaletimo v rob sveta, se obrnemo
    if ycor >= zemlja-vrh [  ;; ce gremo nazaj na nebo
      ifelse temperatura > 20 + random 40
              ;; toplota prihaja le iz majhnega podrocja
              ;; zaradi tega model dobro izgleda, ampak to prispeva tudi
              ;; k meji, na kateri se toplota lahko izgubi
              and xcor > 0 and xcor < max-pxcor - 8
        [ set breed IRi                    ;; pustimo, da nekaj toplote pobegne kot IR
          set heading 20
          set color magenta ]
        [ set heading 100 + random 160 ] ;; vrnemo jih na Zemljo
    ]
  ]
end

to pozeni-IR
  ask IRi [
    if not can-move? 0.3 [ die ]
    fd 0.3
    if ycor <= zemlja-vrh [   ;; spremeni jih v toploto, ce spet pridejo na Zemljino povrsje
      set breed toplote
      rt random 45
      lt random 45
      set color red - 2 + random 4
    ]
    if any? CO2i-here    ;; preveri za trcenje s CO2
      [ set heading 180 - heading ]
  ]
end

to dodaj-CO2  ;; nakljucno doda 25 molekul CO2 v atmosfero
  let nebo-visina nebo-vrh - zemlja-vrh
  create-CO2i 25 [
    set color green
    ;; izberi nakljucno pozicijo na nebu
    setxy random-xcor
          zemlja-vrh + random-float nebo-visina
  ]
end

to odstrani-CO2 ;; nakljucno odstrani 25 molekul CO2
  repeat 25 [
    if any? CO2i [
      ask one-of CO2i [ die ]
    ]
  ]
end

to pozeni-CO2
  ask CO2i [
    rt random 51 - 25 ;; malo obrni
    let razdalja 0.05 + random-float 0.1
    ;; obdrzi CO2 na nebu
    if [not shade-of? blue pcolor] of patch-ahead razdalja
      [ set heading 180 - heading ]
    fd razdalja ;; premakne malo naprej
  ]
end


; *** NetLogo 4.0.4 Model Obvestilo o kopiranju ***
;
; Pravice za kopiranje: 2007 Uri Wilensky.  Vse pravice pridrzane.
;
; Program je dovoljeno uporabljati, spreminjati in redistribuirati,
; ce sta izpolnjeni obe sledeci zahtevi:
; a) vkljuceno je to obvestilo o kopiranju,
; b) ta model ne bo redistribuiran za dobicek brez dovoljenja
;    Urija Wilenskyja.
; Kontaktirajte Urija Wilenskyja za primerna dovoljenja za redistribucijo za
; dobicek.
;
; Ce zelite navesti ta model v akademskih publikacijah, uporabite:
; Tinker, R. and Wilensky, U. (2007). NetLogo Climate Change model.
; http://ccl.northwestern.edu/netlogo/models/ClimateChange.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; V drugih publikacijah uporabite:
; Copyright 2007 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/ClimateChange
; for terms of use.
;
; *** NetLogo 4.0.4 Model Konec obvestila o kopiranju ***
@#$#@#$#@
GRAPHICS-WINDOW
367
12
916
384
24
-1
11.0
1
10
1
1
1
0
1
0
1
-24
24
-8
22
1
1
1
Dotiki

CC-WINDOW
5
437
925
532
Command Center
0

BUTTON
6
12
101
45
nastavi
nastavi
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
100
12
195
45
začni
zacni
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
18
47
191
80
sonce-svetloba
sonce-svetloba
0
5
1
0.2
1
NIL
HORIZONTAL

SLIDER
18
82
191
115
albedo
albedo
0
1
0.6
0.05
1
NIL
HORIZONTAL

PLOT
9
212
278
423
Globalna temperatura
NIL
NIL
0.0
10.0
10.0
20.0
true
false
PENS
"default" 1.0 0 -2674135 true

BUTTON
8
161
105
194
dodaj CO2
dodaj-CO2
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
104
161
208
194
odstrani CO2
odstrani-CO2
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
247
105
340
150
temperatura
temperatura
1
1
11

BUTTON
8
122
110
155
dodaj oblake
dodaj-oblak
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
109
122
225
155
odstrani oblake
odstrani-oblak
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
247
154
340
199
količina CO2
count CO2i
2
1
11

BUTTON
240
41
342
75
opazuj žarek
watch one-of zarki\nask subject [ pd ]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

@#$#@#$#@
KAJ JE TO?
----------
To je model o pretoku energije na Zemlji, konkretno o pretoku toplotne energije. Zemlja je obarvana z roza barvo, površje planeta pa predstavlja ozek črn pas. Nad njim
je modra atmosfera in na vrhu črno vesolje. Atmosferi lahko dodajamo oblake in molekule ogljikovega dioksida (CO2). Molekule CO2 predstavljajo toplogredne pline, ki blokirajo infrardečo svetlobo, ki jo oddaja Zemlja. Oblaki blokirajo prispele in odbite sončne žarke in s tem vplivajo na segrevanje ali ohlajanje planeta.


KAKO DELUJE
-----------
Tok rumenih puščic proti tlom predstavlja sončno energijo. Nekaj sončne svetlobe se odbije od oblakov, še več pa se je lahko odbije od Zemljinega površja.

Če Zemlja absorbira sončno svetlobo, se spremeni v rdečo piko, ki predstavlja toplotno energijo. Vsaka pika predstavlja energijo ene rumene puščice sončne svetlobe. Rdeče pike se naključno premikajo po Zemlji in njena temperatura je povezana s celotnim številom rdečih pik.

Včasih se rdeče pike spremenijo v infrardečo (IR) svetlobo, ki se giblje proti vesolju in odnaša energijo. Verjetnost, da rdeča pika postane IR svetloba, je odvisna od Zemljine temperature. Če je Zemlja mrzla, se le malo rdečih pik spremeni v IR svetlobo; če pa je Zemlja vroča, se spremeni večina. IR energijo predstavljajo piščice barve magneta. Vsaka nosi enako energijo kot rumena puščica in rdeča pika. IR svetloba gre skozi oblake, ne more pa preko molekul CO2.

Obstaja povezava med številom rdečih pik v Zemlji in temperaturo Zemlje. To je zato, ker se Zemljina temperatura poveča, ko naraste celotna toplotna energija. Toplotno energijo dodaja sončna svetloba, ki doseže Zemljo, in IR svetloba, ki se odbije na Zemljo. Termalno energijo odnaša IR svetloba, ki jo emitira Zemlja. Ravnovesje teh določa energijo Zemlje, ki je sorazmerna z Zemljino temperaturo.

V tem modelu je seveda veliko poenostavitev. Zemlja nima povsod enake temperature, enakega albeda in enake nagnjenosti k segrevanju. Nekaj vidne svetlobe absorbira CO2 in nekaj IR svetlobe prodre skozi oblake. Noben model ni povsem natančen. Pomembno pa je, da model na nek način reagira kot sistem, ki naj bi ga modeliral. Ta model to počne in tako kaže, kako CO2 in drugi plini, ki absorbirajo IR svetlobo, povzročajo vpliv tople grede.


KAKO GA UPORABLJATI
-------------------
Drsnik SONČNA SVETLOBA nadzira, koliko sončne energije vstopi v Zemljino atmosfero. Vrednost 1.0 ustreza našemu Soncu. Višje vrednosti omogočajo, da vidimo, kaj bi se zgodilo, če bi bila Zemlja bližje Soncu ali če bi Sonce postalo svetlejše.

Drsnik ALBEDO nadzira, koliko sončne energije, ki pride na Zemljo, se absorbira. Če je albedo 1.0, Zemlja odbije vso sončno svetlobo. To bi se lahko zgodilo, če bi Zemlja zmrznila, in je označeno z belim površjem. Če je albedo nič, Zemlja absorbira vso sončno svetlobo. To je označeno s črnim površjem. Zemljin albedo je okrog 0.6.

Z gumboma lahko dodaš in odstraniš oblake. Oblaki blokirajo sončno svetlobo, ne pa IR svetlobe.

Lahko dodaš in odstraniš toplogredne pline, ki jih predstavljajo molekule CO2. CO2 blokira IR svetlobo, ne pa sončne svetlobe. Gumba dodajata in odvzemata molekule v skupinah po 25 do 150.

Temperatura Zemlje je povezana s količino energije na Zemlji. Več rdečih pik kot vidiš, topleje je.


KAJ LAHKO OPAZUJEMO
-------------------
Opazuj eno puščico sončne svetlobe. Lažje bo, če upočasniš model z drsnikom, ki je na vrhu. Lahko uporabiš tudi gumb OPAZUJ ŽAREK.

Kaj se zgodi s puščico, ko zadene Zemljo? Opiši njeno nadaljnjo pot. Ali pobegne Zemlji? Kaj se zgodi potem? Ali imajo vse puščice podobno pot?


KAJ LAHKO POSKUSIMO
-------------------
1. Igraj se z modelom. Spremeni albedo in poženi model. Modelu dodaj oblake in CO2 in potem opazuj eno puščico sončne svetlobe. Kolikšno največjo temperaturo na Zemlji lahko dosežeš?

2. Poženi model s svetlim Soncem, a brez oblakov in CO2. Kaj se zgodi s temperaturo? Morala bi se hitro dvigniti in potem umiriti pri okrog 50 stopinjah. Zakaj neha naraščati? Zakaj se še kar naprej giblje okrog 50 stopinj? Spomni se, da je temperatura odvisna od števila rdečih pik na Zemlji. Ko je temperatura konstantna, je približno enako prihajajočih rumenih puščic in odhajajočih puščic IR svetlobe. Zakaj?

3. Raziskuj vpliv albeda, vse drugo konstantno pa naj bo konstantno. Ali naraščanje albeda poveča ali zmanjša Zemljino temperaturo? Ko eksperimentiraš, se prepričaj, da model teče dovolj dolgo, da se temperatura ustali.

4. Raziskuj vpliv oblakov, vse drugo pa naj bo konstantno.

5. Raziskuj vpliv dodajanja 100 molekul CO2. Kaj je vzrok spremembi, ki jo opaziš? Zdaj sledi eni puščici sončne svetlobe.


RAZŠIRITEV MODELA
-----------------
Poskusi dodati nekaj drugih faktorjev, ki vplivajo na Zemljino temperaturo. Dodaš lahko npr. zelena področja in potem pogledaš, kaj se zgodi, ko jih ljudje uničijo. Lahko bi poskusil modelu dodati tudi spremenljiv albedo, namesto da je enaka vrednost za cel planet. Lahko bi imel ledenike z visokim albedom in morja z nizkim albedom in potem ocenil, kaj se zgodi, ko se ledeniki stopijo v morja.


OBLIKE V NETLOGU
----------------
Upoštevaj, da so oblaki pravzaprav narejeni iz veliko majhnih okroglih želvic.


SORODNI MODELI
--------------
Daisyworld


ZASLUGE IN PRIPOROČILA
----------------------
Ta model temelji na prvotni verziji, ki jo je leta 2005 ustvaril Robert Tinker za projekt TELS.

Če želite navesti ta model v akademskih publikacijah, uporabite:  Tinker, R. and Wilensky, U. (2007).  NetLogo Climate Change model.  http://ccl.northwestern.edu/netlogo/models/ClimateChange.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

V drugih publikacijah uporabite:  Copyright 2007 Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/ClimateChange for terms of use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cloud
false
0
Circle -7500403 true true 13 118 94
Circle -7500403 true true 86 101 127
Circle -7500403 true true 51 51 108
Circle -7500403 true true 118 43 95
Circle -7500403 true true 158 68 134

co2-molecule
true
0
Circle -1 true false 183 63 84
Circle -16777216 false false 183 63 84
Circle -7500403 true true 75 75 150
Circle -16777216 false false 75 75 150
Circle -1 true false 33 63 84
Circle -16777216 false false 33 63 84

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

molecule water
true
0
Circle -1 true false 183 63 84
Circle -16777216 false false 183 63 84
Circle -7500403 true true 75 75 150
Circle -16777216 false false 75 75 150
Circle -1 true false 33 63 84
Circle -16777216 false false 33 63 84

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

ray
true
0
Line -7500403 true 150 0 150 315
Line -7500403 true 120 255 150 225
Line -7500403 true 150 225 180 255
Line -7500403 true 120 165 150 135
Line -7500403 true 120 75 150 45
Line -7500403 true 150 135 180 165
Line -7500403 true 150 45 180 75

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.4
@#$#@#$#@
setup add-cloud add-cloud add-cloud repeat 800 [ go ]
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@