globals
[
  mreza-x                       ;; dolžina odsekov med dvema cestama v x smeri
  mreza-y                       ;; dolžina odsekov med dvema cestama v y smeri
  pospesek                      ;; konstanta, ki kontrolira kako zelo bo avto pospešil ali upočasnil, če bo to potrebno
  faza                          ;; spremlja faze
  st-ustavljenih-avtomobilov    ;; število avtomobilov, ki so se ustavili med enim prečkanjem pozeni procedure
  trenutna-luc                  ;; trenutno izbrana luc

  ;; odsekovni deli
  krizisca       ;; križišča
  ceste          ;; deli, ki vsebujejo samo oseke, ki so ceste
]
turtles-own
[
  hitrost     ;; hitrost vozila
  ver-avto?   ;; true, če se avto vozi navzdol in false če gre v desno
  cas-cakanja ;; dolžina časa, odkar se je avto nazadnje premaknil
]

patches-own
[
  krizisce?       ;; true če je odsek na križišču dveh cest
  gori-zelena-luc? ;; true če gori zelena luč v križišču, sicer false.
                  ;; false za odseke, ki niso križišča
  moja-vrsta      ;; število izbrane vrste. Vrste se začnejo šteti od skrajne zgornje 
                  ;;strani sveta.  -1 za območja izven
  moj-stolpec     ;; število izbranega stoplpca. Stolpci se začnejo šteti od skrajne leve 
                  ;;strani sveta.  -1 za območja izven 
  moja-faza       ;; faza luči vkrižišču.  -1 za območja brez križišč.
  avto?           ;; ali se bo luč spremenila avtomatično.
                  ;; false za območja brez križišč.
]


;;;;;;;;;;;;;;;;;;;;;;;
;; nastavi procedura ;;
;;;;;;;;;;;;;;;;;;;;;;;

;; Začetno stanje na ekranu je določeno s podajanje globalnih in odsekovnih začetnih vrednosti.
;; Ustvari st-avtomobilov avtomobilov, če je dovolj cestnih odsekov, da lahko za vsak avto
;; ustvarimo en odsek. Nastavitev grafov.
to nastavi
  ca
  nastavi-globals
  ;; Prvo narišemo vse dele in nastavimo spremenjlivke
  nastavi-patches
  naredi-trenutno one-of krizisca
  oznaci-trenutno

  set-default-shape turtles "car"

  if (st-avtomobilov > count ceste)
  [
    user-message (word "Preveč avtomobilov je na cesti. "
                       "Ali povečaj število cest "
                       "s povečanjem količine na drsniku x-dimenzija ali "
                       "y-dimenzija ali zmanjšaj število avtomobilov "
                       "z zmanjšanjem količine na drsniku st-avtomobilov.\n"
                       "Nastavitev se je ustavila.")
    stop
  ]

  ;; Sedaj ustvari avtomobile in za vsakega od avtomobilov pokliči funkcijo nastavi-avtomobile
  ;;in funkcijo nastavi-barvo-avta.
  
  crt st-avtomobilov
  [
    nastavi-avtomobile
    nastavi-barvo-avta
    shrani-podatek
  ]

  ;; daj avtomobilom začetno hitrost
  ask turtles [ nastavi-avtomobilovo-hitrost ]

  nastavi-grafe
end

;; Nastavi globalno spremenljivko na primerne spremenjlivke
to nastavi-globals
  set trenutna-luc nobody ;; samo za začetek, ker še ni nobenih luči
  set faza 0
  set st-ustavljenih-avtomobilov 0
  set mreza-x world-width / x-dimenzija
  set mreza-y world-height / y-dimenzija

  ;; pospešek naj ne bo 0.1, dokler lahko pride do napake pri kroženju in končal na končnem delu
  set pospesek 0.099
end

;; Odseki morajo biti prave barve, nastavi ceste in krizisca na začetno vrednost,
;; in nastavi semaforje na eno nastavitev
to nastavi-patches
  ;; nastavi začetne spremenljivke za odseke na začetne vrednosti in barve
  ask patches
  [
    set krizisce? false
    set avto? false
    set gori-zelena-luc? true
    set moja-vrsta -1
    set moj-stolpec -1
    set moja-faza -1
    set pcolor brown + 3
  ]

  ;; nastavi globalne spremenljivke, da se skladajo z odsekovnimi nastavitvami
  set ceste patches with
    [(floor((pxcor + max-pxcor - floor(mreza-x - 1)) mod mreza-x) = 0) or
    (floor((pycor + max-pycor) mod mreza-y) = 0)]
  set krizisca ceste with
    [(floor((pxcor + max-pxcor - floor(mreza-x - 1)) mod mreza-x) = 0) and
    (floor((pycor + max-pycor) mod mreza-y) = 0)]

  ask ceste [ set pcolor white ]
  nastavi-krizisca
end

;; Nastavi primerno nastavitev za krizisce?, moja-vrsta in moj-stoplec.
;; Nastavi tako, da bodo vse luči na začetku v horizontalni smeri rdeče, 
;; vertikalni pa zelene.
to nastavi-krizisca
  ask krizisca
  [
    set krizisce? true
    set gori-zelena-luc? true
    set moja-faza 0
    set avto? true
    set moja-vrsta floor((pycor + max-pycor) / mreza-y)
    set moj-stolpec floor((pxcor + max-pxcor) / mreza-x)
    nastavi-barvo-luci
  ]
end

;; Nastavi spremenljivke avtomobila na primerne vrednosti in postavi avto na prazen del cestnega odseka.
to nastavi-avtomobile  ;; procedura avtomobila
  set hitrost 0
  set cas-cakanja 0
  daj-na-prazno-cesto
  ifelse krizisce?
  [
    ifelse random 2 = 0
    [ set ver-avto? true ]
    [ set ver-avto? false ]
  ]
  [
    ;; če je avto na vertikalni cesti (raje, kot na vodoravni)
    ifelse (floor((pxcor + max-pxcor - floor(mreza-x - 1)) mod mreza-x) = 0)
    [ set ver-avto? true ]
    [ set ver-avto? false ]
  ]
  ifelse ver-avto?
  [ set heading 180 ]
  [ set heading 90 ]
end

;; Najdi cestni odsek brez avtov in tja postavi avto.
to daj-na-prazno-cesto  ;; postavitev avtomobila
  move-to one-of ceste with [not any? turtles-on self]
end

;; nastavi grafe
to nastavi-grafe
  set-current-plot "ustavljeni avtomobili"
  set-plot-y-range 0 st-avtomobilov
  plot st-ustavljenih-avtomobilov

  set-current-plot "povprečni čas čakanja"
  plot mean [ cas-cakanja ] of turtles

  set-current-plot "povprečna hitrost avtomobilov"
  set-plot-y-range 0 omejitev-hitrosti
  plot mean [ hitrost ] of turtles
end


;;;;;;;;;;;;;;;;;;;;;;
;; Poženi procedura ;;
;;;;;;;;;;;;;;;;;;;;;;

;; požene simulacijo
to pozeni

  osvezi-trenutno

  ;; naredi, da križišča menjajo barvo
  nastavi-signals
  set st-ustavljenih-avtomobilov 0

  ;; nastavi hitrost avtomobila za čas tega izvajanja, h kateri strmijo,
  ;; shranjuje podatke za risanj grafov in nastavi barvo avtomobilov na 
  ;;primerno barvo glede na hitrost.
    ask turtles
  [
    nastavi-avtomobilovo-hitrost
    fd hitrost
    shrani-podatek
    nastavi-barvo-avta
  ]

  ;; nadgrajuje grafe z novimi podatki o prečkanjih med proceduro
  risi-graf
  ;; nadgrajuje podatke o fazah in globalnem času
  naslednja-faza
  tick
end

to izberi-trenutno
  if mouse-down?
  [
    let x-mis mouse-xcor
    let y-mis mouse-ycor
    if [krizisce?] of patch x-mis y-mis
    [
      osvezi-trenutno
      oznaci-trenutno
      naredi-trenutno patch x-mis y-mis
      oznaci-trenutno
      stop
    ]
  ]
end

;; nastavi trenutno luč in vmesno ploskev, da jo lahko spremeniš.
to naredi-trenutno [luc]
  set trenutna-luc luc
  set trenutna-faza [moja-faza] of trenutna-luc
  set trenutni-avto? [avto?] of trenutna-luc
end

;; nadgradi podatke spremenjljivkam za trenutno luč 
to osvezi-trenutno
  ask trenutna-luc [
    set moja-faza trenutna-faza
    set avto? trenutni-avto?
  ]
end

;; označi trenutno luč
to oznaci-trenutno
  ask trenutna-luc
  [
    ask patch-at -1 1
    [
      set plabel-color black
      set plabel "trenutno"
    ]
  ]
end

;; odznači trenutno luč (ker smo izbrali novo)
to odznaci-trenutno
  ask trenutna-luc
  [
    ask patch-at -1 1
    [
      set plabel ""
    ]
  ]
end

;; spremeni luč na semaforju, če je faza v vsakem križišču enaka moja-faza
to nastavi-signals
  ask krizisca with [avto? and faza = floor ((moja-faza * dolzina-cikla) / 100)]
  [
    set gori-zelena-luc? (not gori-zelena-luc?)
    nastavi-barvo-luci
  ]
end

;; Ta procedura preveri spremenljivko gori-zelena-luc? na vsakem križišču in nastavlja
;; luči na semaforju, da imajo zeleno luč gor ali zeleno na levo.
to nastavi-barvo-luci  ;; procedura v križišču
  ifelse elektrika?
  [
    ifelse gori-zelena-luc?
    [
      ask patch-at -1 0 [ set pcolor red ]
      ask patch-at 0 1 [ set pcolor green ]
    ]
    [
      ask patch-at -1 0 [ set pcolor green ]
      ask patch-at 0 1 [ set pcolor red ]
    ]
  ]
  [
    ask patch-at -1 0 [ set pcolor white ]
    ask patch-at 0 1 [ set pcolor white ]
  ]
end

;; nastavi hitrost avtomobila glede na to ali so pred rdečo lučjo ali glede na hitrost
;; avtomobila (če je kakšen) na poti pred njim
to nastavi-avtomobilovo-hitrost  ;; procedura za avtomobile
  ifelse pcolor = red
  [ set hitrost 0 ]
  [
    ifelse ver-avto?
    [ nastavi-hitrost 0 -1 ]
    [ nastavi-hitrost 1 0 ]
  ]
end

;; nastavi spremenjlivko hitrosti avtomobila na primerno vrednost (ne prekoračiti
;; omejitve hitrosti)glede na to ali so pred vozilom še kakšni avtomobili
to nastavi-hitrost [ delta-x delta-y ]  ;; procedura za avtomobile
  ;; avto je pred vozilom
  let avtomobili-spredaj turtles-at delta-x delta-y

  ;; če je vozilo pred vozilom, je treba upočasniti
  ;; drugače, pospešiti
  ifelse any? avtomobili-spredaj
  [
    ifelse any? (avtomobili-spredaj with [ ver-avto? != [ver-avto?] of myself ])
    [
      set hitrost 0
    ]
    [
      set hitrost [hitrost] of one-of avtomobili-spredaj
      upocasni
    ]
  ]
  [ hitrost-gor ]
end

;; upočasni hitrost vozila
to upocasni  ;; procedura za avtomobile
  ifelse hitrost <= 0  ;;če je hitrost < 0
  [ set hitrost 0 ]
  [ set hitrost hitrost - pospesek ]
end

;; povečamo hitrost vozila
to hitrost-gor  ;; procedura za atvomobile
  ifelse hitrost > omejitev-hitrosti
  [ set hitrost omejitev-hitrosti ]
  [ set hitrost hitrost + pospesek ]
end

;; nastavi barvo vozila, glede na to, kako hitro se premika
to nastavi-barvo-avta  ;; procedura za avtomobile
  ifelse hitrost < (omejitev-hitrosti / 2)
  [ set color blue ]
  [ set color cyan - 2 ]
end

;; spremlja število ustavljenih avtomobilov in meri čas, ko vozila stojijo,
;; če je njihova hitrost 0.
to shrani-podatek  ;; procedura za avtomobile
  ifelse hitrost = 0
  [
    set st-ustavljenih-avtomobilov st-ustavljenih-avtomobilov + 1
    set cas-cakanja cas-cakanja + 1
  ]
  [ set cas-cakanja 0 ]
end

to zamenjaj-trenutno
  ask trenutna-luc
  [
    set gori-zelena-luc? (not gori-zelena-luc?)
    nastavi-barvo-luci
  ]
end

;; faza cikla nastavi na naslednjo promesno vrednost
to naslednja-faza
  ;; Faza cikla gre od 0 do dolzina-cikla in potem ponovno od začetka.
  set faza faza + 1
  if faza mod dolzina-cikla = 0
    [ set faza 0 ]
end


;;;;;;;;;;;;;;;;;;;;
;; Risanje grafov ;;
;;;;;;;;;;;;;;;;;;;;

;; graf s podatki, ki jih dobiva skozi izvajanje pozeni procedure
to risi-graf
  narisi-novo-vrednost "ustavljeni avtomobili" st-ustavljenih-avtomobilov
  narisi-novo-vrednost "povprečni čas čakanja" mean [ cas-cakanja ] of turtles
  narisi-novo-vrednost "povprečna hitrost avtomobilov" mean [ hitrost ] of turtles
end

to narisi-novo-vrednost [ ime-grafa vrednost ]
  set-current-plot ime-grafa
  plot vrednost
end


; *** NetLopozeni 4.0.4 Model Copyright Notice ***
;
; This model was created as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) --
; grant numbers REC #9814682 and REC-0126227.
;
; Copyright 2003 by Uri Wilensky.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2003).  NetLopozeni Traffic Grid model.
; http://ccl.northwestern.edu/netlopozeni/models/TrafficGrid.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 2003 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlopozeni/models/TrafficGrid
; for terms of use.
;
; *** End of NetLopozeni 4.0.4 Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
327
10
670
374
18
18
9.0
1
12
1
1
1
0
1
1
1
-18
18
-18
18
1
1
1
ticks

CC-WINDOW
5
556
680
651
Command Center
0

PLOT
453
377
671
541
povprečni čas čakanja
čas
povprečni čas
0.0
100.0
0.0
5.0
true
false
PENS
"default" 1.0 0 -2674135 true

PLOT
228
377
444
542
povprečna hitrost avtomobilov
čas
povprečna hitrost
0.0
100.0
0.0
1.0
true
false
PENS
"default" 1.0 0 -2674135 true

SLIDER
108
35
205
68
y-dimenzija
y-dimenzija
1
9
6
1
1
NIL
HORIZONTAL

SLIDER
12
35
106
68
x-dimenzija
x-dimenzija
1
9
2
1
1
NIL
HORIZONTAL

SWITCH
12
107
120
140
elektrika?
elektrika?
0
1
-1000

SLIDER
12
71
293
104
st-avtomobilov
st-avtomobilov
1
400
213
1
1
NIL
HORIZONTAL

PLOT
5
376
219
540
ustavljeni avtomobili
čas
ustavljeni avti
0.0
100.0
0.0
100.0
true
false
PENS
"default" 1.0 0 -2674135 true

BUTTON
221
184
288
217
poženi
pozeni
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
208
35
292
68
nastavi
nastavi
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
11
177
165
210
omejitev-hitrosti
omejitev-hitrosti
0
1
0
0.1
1
NIL
HORIZONTAL

MONITOR
205
132
330
177
trenutna faza
faza
3
1
11

SLIDER
11
143
165
176
dolzina-cikla
dolzina-cikla
1
100
20
1
1
NIL
HORIZONTAL

SLIDER
146
256
302
289
trenutna-faza
trenutna-faza
0
99
0
1
1
%
HORIZONTAL

BUTTON
9
292
143
325
spremeni luč
zamenjaj-trenutno
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
9
256
144
289
trenutni-avto?
trenutni-avto?
0
1
-1000

BUTTON
145
292
300
325
izberi križišče
izberi-trenutno
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

@#$#@#$#@
KAJ JE TO?
-----------
Nadziraš semaforje in vse spremenljivke, kot so omejitev hitrosti, število avtomobilov, v realnem simuliranju prometa. Na takšen način lahko raziskuješ dinamiko prometa, kar lahko uporabiš v različnih področjih študija. Od računskega do socialnih študijev.

Poskusi razviti strategije za izboljšanje prometa in razumeti različne načine merjenja kvalitete prometa.


KAKO DELUJE
------------
Na vsakem koraku se bodo avtomobili vozili s trenutno hitrostjo. Če je njihova hitrost manjša od trenutne omejitve hitrosti in pred sabo nimajo nobenega avtomobila pred sabo, potem pospešujejo. Če je pred njimi počasnejši avto, potem njihova hitrost pojema do hitrosti avtomobila, ki je spredaj.Če gori rdeča luč ali je pred njimi avto, ki stoji, potem se ustavijo.

Obstajata dva načina, kako se luči menjavajo. Prvi način: uporabnik lahko zamenja katerokoli luč ob kateremkoli času in potem pritisne tipko ZAMENJAJ LUČ. Drugi način: luči se lahko menjajo avtomatično, enkrat na cikel. Uvodoma s ebodo vse luči avtomatično zamenjale na začetku vsakega cikla.


KAKO UPORABLJATI
-------------
Spremeni prometno mrežo (Uporabljaš drsnika X-DIMENZIJA in Y-DIMENZIZJA, da dobiš željeno število semforjev. Spremeni katerokoli od nastavitev, ki bi jih rad/a spremenil/a. Pritisni NASTAVI gumb.

Sedaj lahko nastaviš luči po želji, s kombinacijo avtomatično/ročno v vsaki fazi. Spremembe trenutnega stanja luči lahko narediš z uporabo naslednjih ukazov TRENUTNI-AVTO?, TRENUTNA-FAZA in SPREMEMBA LUČI. Lahko tudi označiš trenutno križišče, če uporabiš ukaz IZBERI KRIŽIŠČE. Poglej spodaj za detajle.

Simulacijo poženeš v tek, če pritisneš gumb POŽENI. Tudi med simulacijo lahko spreminjaš luči.

Gumbi:

NASTAVI - zgenerira novo prometno mrežo glede na trenutne podatke X-DIMENZIJA in Y-DIMENZIJA in ST-AVTOMOBILOV število avtomobilov. To hkrati zbriše vse ostalo. Vse luči so nastavljene na avtomatično spreminjanje in vse faze so nastavljene na 0.
POŽENI- požene simulacijo do preklica
SPREMENI LUČ- spremeni smer prometa, ki bi šel čez trenutno luč. Luč lahko zamenjaš ročno tudi, ko program dela avtomatičen način.
IZBERI KRIŽIŠČE- ti omogoča, da izbereš novi "trenutni" semafor. Ko je gimb pritisnjen, pritisni na željeno križišče, ki bi ga rad/a imel/a za trenutnega. Ko označiš križišče, bo "trenutna" oznaka šla na novo križišče in bo gumb avtomatično skožil ven. 

Drsniki:

OMEJITEV-HITROSTI - nastavi maksimalno hitrost za avtomobile 
ST-AVTOMOBILOV - nastavi število avtomobilov v simulaciji (moraš pritisniti NASTAVI gumb, da vidiš spremembo)
DOLZINA-CIKLA - nastavi koliko časovnih enot bo minilo za vsak cikel. To nima nobenega vpliva na ročno nastavitev luči. To ti bo omogočalo, da povečaš ali zmanjšaš pogostost, s katero lahko luči avtomatično spremeniš.
X-DIMENZIJA - nastaviš število vertikalnih cest (moraš pritisniti NASTAVI gumb, da vidiš spremembe)
Y-DIMENZIJA - nastaviš število horizontalnih cest (moraš pritisniti NASTAVI gumb da vidiš spremembe)
TRENUTNA-FAZA - kontrolira kdaj se trenutna luč spremeni, če je nastavljeno na avtomatski način. Vrednost na drsniku predstavlja odstotek časa v ciklu, ko se trenutna luč zamenja. Torej, če je DOLZINA-CIKLA nastavljena na 20 in je TRENUTNA-FAZA na 75%, potem se bo trenutna lučspremenila na 15ti enoti vsakega cikla.


Stikala:
ELEKTRIKA? - določa prisotnost semaforjev
TRENUTNI-AVTO? - določa ali se bodo luči vklapljale na avtomatični način, kjer se spremenijo enkrat na cikel (glede na TRENUTNA-FAZA), in med ročnim načinom, kjer jih direktno kontroliraš z SPREMENI LUČ.

Grafi:

USTAVLJENI AVTOMOBILI - prikazuje število ustavljenih avtomobilov v celotnem času
POVPREČNA HITROST AVTOMOBILOV - prikazuje povprečno hitrost avtomobilov v celotnem času
POVPREČNI ČAS ČAKANJA - prikazuje povprečni čas ustavljanja avtomobilov v celotnem času


STVARI ZA RAZMISLIT
----------------
Ko so se avtomobili ustavili in potem ponovno speljali, se bo prometni zamašek premikal nazaj, četudi se bodo avtomobili premikali naprej. Zakaj je tako?

Ko je ELEKTRIKA? izklopljena in je malo avtomobilov na ulicah, se "zastoj" ponavadi zgodi kmalu. Zastoj je lahko tako hud, da v celoti zaustavi promet. Zakaj je tako, da se noben avto ne more premikati naprej, da bi prekinil ta zastoj? Ali bi se to lahko zgodilo v realnosti?

Zastoj se lahko zgodi tudi, če je elektrika vklopljena. Kakšne situacije lahko sprožijo zastoje?


STVARI ZA POSKUSIT
-------------
Poskusi spreminjati omejitev hitrosti za avtomobile. Kako to vpliva na vsesplošno učinkovitost prometnega pretoka? Ali se manj avtomobilov ustavlja krajši čas? Ali je POVPREČNA HITROST AVTOMOBILOV višja ali nižja glede na prej?

Poskusi spreminjati število avtomobilov na ulicah. Ali to vpliva na učinkovitost prometnega pretoka?

Kaj pa če preminjaš hitrost simulacije? Ali to vpliva na učinkovitost prometnega pretoka?

Poskusi zagnati to simulacijo z vsemi lučmi na avtomatičen način spreminjanja. Je težje narediti dobro premikanje prometa, če uporabljamo to sceno, kot če bi sami kontrolirali luči ročno? Zakaj?

Poskusi zagnati to simulacijo z vsemi lučmi na avtomatičen način. Poskusi najti način pri nastavitvah faz semaforskih luči, da bo POVPREČNA HITROST AVTOMOBILOV največja.
Sedaj poskusi zminimalizirati število ustavljenih avtomobilov. Sedaj poskusi zmanjšati povprečen čas čakanja avtomobilov. Je sedaj kakšna povezava med temi različnimi metrikami?


RAZŠITITEV MODELA
-------------------
Na splošno je maksimalna omejitev hitrosti (najdena na drsniku OMEJITEV-HITROSTI) za avtomobile 1.0. To je zaradi tega dejstva, ker morajo avtomobili vnaprej gledati na hitrost s katero potujejo, da vidijo, če so avtomobili pred njimi.
Če jih ni, pospešijo. Če so, se upočasnijo. Gledati vnaprej, za vrednost višjo od 1, je malce kočljivo. Poskusi premisliti, kakšno bo pravilno obnašanje za hitrosti višje od 1.

Ko avto doseže konec sveta, se pojavi na drugi strani. Kaj bi bilo, če bi takrat izginil in bi novi avtomobili prihajali v mesto na naključnih lokacijah in intervalih?


NETLOGO PREDSTAVLJA
----------------
Ta model uporablja dva večna gumba, ki sta lahko aktivna istočasno, da omogoča uporabniku, da izbere novo trenutno križišče medtem, ko se model izvaja.

Hkrati omogoča uporabniku, da lahko izbira med večimi možnimi grafi ali da jih prikaže vse hkrati.


SORODNI MODELI
--------------	
Traffic Basic simulira tok ene enosmerne ulice
Traffic 2 Lanes doda novo ulico v prometu
Traffic Intersection simulira eno križišče

HubNetova aktivnost Gridlock (zastoj) ima veliko podobnih funkcionalnosti in omogoča množico uporabnikov, da kontrolirajo avtomobile na poseben način.


VPLIV IN PRIPOROČILA
----------------------
Da se sklicuješ na tamodel v akademskih publikacijah, prosim uporabi: Wilensky, U. (2003).  NetLogo Traffic Grid model.  http://ccl.northwestern.edu/netlogo/models/TrafficGrid.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL. 

V ostalih publikacijah, prosim uporabi: Copyright 2003 Uri Wilensky.  Vse pravice pridržane.  Poglej http://ccl.northwestern.edu/netlogo/models/TrafficGrid za pravila uporabe.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
true
0
Polygon -7500403 true true 180 15 164 21 144 39 135 60 132 74 106 87 84 97 63 115 50 141 50 165 60 225 150 285 165 285 225 285 225 15 180 15
Circle -16777216 true false 180 30 90
Circle -16777216 true false 180 180 90
Polygon -16777216 true false 80 138 78 168 135 166 135 91 105 106 96 111 89 120
Circle -7500403 true true 195 195 58
Circle -7500403 true true 195 47 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@