globals [
  weeks             
  infection-chance
  symptoms-show     
  slider-check-1   
  slider-check-2    
  slider-check-3    
  slider-check-4
]

turtles-own [
  infected?          
  known?             
  infection-length  
  coupled?           
  couple-length    
  commitment        
  coupling-tendency  
  condom-use         
  test-frequency    
  partner          
]


to setup
  ca
  setup-globals
  setup-people
  setup-plot
  update-plot
end

to setup-globals
  set weeks 0
  set infection-chance 50                         
  set symptoms-show 200.0    
  set slider-check-1 povprecno-trajanje-zveze
  set slider-check-2 povprecna-spolna-aktivnost
  set slider-check-3 povprecno-st-uporabnikov-kondoma
  set slider-check-4 frekvenca-testiranja
end

to setup-people
  cct zacetna-populacija
    [ setxy (random-float screen-size-x)
            (random-float screen-size-y)
      set known? false
      set coupled? false
      set partner nobody
      ifelse random 2 = 0
        [ set shape "person righty" ]
        [ set shape "person lefty" ]
      set infected? (who < zacetna-populacija * 0.025)
      if infected?
        [ set infection-length random-float symptoms-show ]
      assign-commitment
      assign-coupling-tendency
      assign-condom-use
      assign-test-frequency
      assign-color ]
end

to assign-color  
  ifelse not infected?
    [ set color green ]
    [ ifelse known?
      [ set color red ]
      [ set color blue ] ]
end

to assign-commitment 
  set commitment random-near povprecno-trajanje-zveze
end

to assign-coupling-tendency 
  set coupling-tendency random-near povprecna-spolna-aktivnost
end

to assign-condom-use  
  set condom-use random-near povprecno-st-uporabnikov-kondoma
end

to assign-test-frequency  
  set test-frequency random-near frekvenca-testiranja
end

to-report random-near [center]  
  let result 0
  repeat 40
    [ set result (result + random-float center) ]
  report result / 20
end

to go
  if (not any? turtles with [not known?])
    [ stop ]
  check-sliders
  set weeks (weeks + 1)
  ask turtles
    [ if infected?
        [ set infection-length infection-length + 1 ]
      if coupled?
        [ set couple-length couple-length + 1 ] ]
  ask turtles
    [ if not coupled?
        [ move ] ]
   ask turtles
    [ if not coupled? and shape = "person righty" and (random-float 10.0 < coupling-tendency)
        [ couple ] ]
  ask turtles [ uncouple ]
  ask turtles [ infect ]
  ask turtles [ test ]
  ask turtles [ assign-color ]
  update-plot
end

to check-sliders
  if (slider-check-1 != povprecno-trajanje-zveze)
    [ ask turtles [ assign-commitment ]
      set slider-check-1 povprecno-trajanje-zveze ]
  if (slider-check-2 != povprecna-spolna-aktivnost)
    [ ask turtles [ assign-coupling-tendency ]
      set slider-check-2 povprecna-spolna-aktivnost ]
  if (slider-check-3 != povprecno-st-uporabnikov-kondoma)
    [ ask turtles [ assign-condom-use ]
      set slider-check-3 povprecno-st-uporabnikov-kondoma ]
  if (slider-check-4 != frekvenca-testiranja )
    [ ask turtles [ assign-test-frequency ]
      set slider-check-4 frekvenca-testiranja ]
end

to move  
  rt random-float 360
  fd 1
end

to couple  
  let potential-partner random-one-of (turtles-at -1 0)
                          with [not coupled? and shape = "person lefty"]
  if potential-partner != nobody
    [ if random-float 10.0 < coupling-tendency-of potential-partner
        [ without-interruption
            [ set partner potential-partner
              set coupled? true
              set coupled?-of partner true
              set (partner-of partner) self
              setxy pxcor pycor 
              ask partner
                [ setxy pxcor pycor ] 
              set pcolor gray
              set pcolor-of (patch-at -1 0) gray ] ] ]
end

to uncouple  
  if coupled? and (shape = "person righty")
    [ if (couple-length > commitment) or
         (couple-length-of partner) > (commitment-of partner)
        [ without-interruption
            [ set coupled? false
              set couple-length 0
              set (couple-length-of partner) 0
              set pcolor black
              set pcolor-of (patch-at -1 0) black
              set (partner-of partner) nobody
              set (coupled?-of partner) false
              set partner nobody ] ] ]
end


to infect  
  if coupled? and infected? and not known?
    [ if random-float 11 > condom-use or
         random-float 11 > (condom-use-of partner)
        [ if random-float 100 < infection-chance
            [ set (infected?-of partner) true ] ] ]
end

to test 
  if random-float 52 < test-frequency
    [ if infected?
        [ set known? true ] ]
  if infection-length > symptoms-show
    [ if random-float 100 < 5
        [ set known? true ] ]
end

to setup-plot
  set-current-plot "Populacija"
  set-plot-y-range 0 (zacetna-populacija + 50)
end

to update-plot
  set-current-plot "Populacija"
  set-current-plot-pen "HIV-"
  plot count turtles with [not infected?]
  set-current-plot-pen "HIV?"
  plot count turtles with [infected?] -
       count turtles with [known?]
  set-current-plot-pen "HIV+"
  plot count turtles with [known?]
end


to-report %infected
  ifelse any? turtles
    [ report (count turtles with [infected?] / count turtles) * 100 ]
    [ report 0 ]
end


; *** Obvestilo o avtorskih pravicah NetLogo modela ***
;
; Model je bil narejen kot del projekta: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  Projekt se zahvaljuje za podporo fundaciji
; National Science Foundation (Applications of Advanced Technologies
; Program) -- številka subvencije RED #9552950 and REC #9632612.
;
; Avtorske pravice 1998 - Uri Wilensky. Vse pravice pridržane.
;
; Dovoljeno je uporabljati, spreminjati in ponovno distributirati ta model,
; kadar sta izpolnjeni naslednji dve zahtevi:
; a) ta navedba avtorskih pravic je vsebovana;
; b) ta model se ne sme distributirati proti plačilu brez dovoljenja in dogovora o licenciranju z avtorjem g. Uri Wilensky.
;
; Ta model je bil spremenjen v NetLogo kot del projekta:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  Projekt se zahvaljuje za podporo fundaciji
; National Science Foundation (REPP program) -- številka subvencije REC #9814682.
; spremenjen iz StarLogoT v NetLogo, 2001.  Popravljen 2002.
;
; Za sklicevanje na ta model v akademskih krogih, prosimo uporabite:
; Wilensky, U. (1998).  NetLogo AIDS model.
; http://ccl.northwestern.edu/netlogo/models/AIDS.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; V ostalih publikacijah, prosimo uporabite:
; Copyright 1998 by Uri Wilensky.  Vse pravice pridržane. Poglejte
; http://ccl.northwestern.edu/netlogo/models/AIDS
; za pravice nadaljne uporabe.
;
; *** Konec obvestila o avtorskih pravicah NetLogo modela ***
@#$#@#$#@
GRAPHICS-WINDOW
362
10
747
416
12
12
15.0
1
10
1
1
1
0
1
1
1

CC-WINDOW
5
430
756
525
Command Center
0

BUTTON
4
42
93
75
nastavitve
setup
NIL
1
T
OBSERVER
T
NIL

BUTTON
4
76
87
109
izvajaj
go
T
1
T
OBSERVER
T
NIL

MONITOR
4
116
87
165
%okuženih
%infected
2
1

MONITOR
4
166
87
215
leta
weeks / 52
1
1

SLIDER
90
42
359
75
zacetna-populacija
zacetna-populacija
50
500
100
1
1
NIL

SLIDER
90
112
359
145
povprecno-trajanje-zveze
povprecno-trajanje-zveze
1.0
200.0
13.0
1
1
tednov

SLIDER
90
77
359
110
povprecna-spolna-aktivnost
povprecna-spolna-aktivnost
0.0
10.0
9.0
1.0
1
NIL

SLIDER
90
147
359
180
povprecno-st-uporabnikov-kondoma
povprecno-st-uporabnikov-kondoma
0.0
10.0
0.0
1.0
1
NIL

SLIDER
90
182
359
215
frekvenca-testiranja
frekvenca-testiranja
0.0
2
0.13
0.01
1
krat/leto

PLOT
4
217
359
416
Populacija
tedni
ljudje
0.0
52.0
0.0
350.0
true
true
PENS
"HIV-" 1.0 0 -10899396 true
"HIV+" 1.0 0 -2674135 true
"HIV?" 1.0 0 -13345367 true

@#$#@#$#@
KAJ DELA? 

Ta model simulira širjenje človeku nevarnega virusa (HIV), ki se prenaša s spolnimi odnosi v mali izolirani človeški populaciji, ki jo opazujemo ter prikazuje posledice njihove spolne aktivnosti.

Kot vemo, se virus HIV širi na različne načine: 
- z nezaščitenimi spolnimi odnosi, 
- preko posojanja okužene igle narkomanov, 
- pri transfuziji z okuženo krvjo, 
- preko okužene matere na otroka, 
- ... 

Naš model prikazuje samo okužbo z virusom HIV pri spolnih odnosih in raziskuje pomembne učinke na populacijo glede na štiri vidike spolnega obnašanja. Uporabnik nastavi povprečno spolno aktivnost začetne populacije, koliko časa povprečen par populacije ostane skupaj, kako pogosta je v populaciji uporaba kondomov in kako pogosto se posamezniki populacije odločajo za testiranje okužbe z virusom HIV. Raziskovanje prve in druge spremenljivke lahko ilustrira, kako so spremembe spolnega  vedenja v naši družbi prispevale k povečanju spolno prenosljivih bolezni, medtem ko raziskovanje tretje in četrte spremenljivke lahko prispeva k začasni rešitvi problema. 

S tem, ko uporabnik lahko nadzira, kako pogosto se bo povprečen posameznik odločil za testiranje, lahko določamo pomembnost nevarnosti HIV za zdravje celotne populacije. Ker se virus takoj ne pokaže v gostitelju, so posamezniki pogosto nekaj časa že okuženi, preden test ali simptomi zmanjšanja imunosti (kar vodi v testiranje) razkrijejo prisotnost virusa HIV. Redno odkrivanje z virusom HIV okuženih posameznikov bi lahko imelo pomemben vpliv na zdravje celotne populacije, če bi poznavanje okužb pozitivno vplivalo na spolno vedenje posameznikov v populaciji. Ta model raziskuje to možnost s tem, da bi vsi posamezniki, ki se zavedajo svoje okužbe z virusom HIV, vedno prakticirali varno spolnost. 


KAKO GA UPORABLJAMO ?

Ta model uporablja izraz par za dva človeka vpletena v spolno razmerje. Posamezniki tavajo po zaslonu, kadar niso del para. Ko pridejo v stik s primernim partnerjem, obstaja možnost, da dva posameznika postaneta par. Če se to zgodi, se tadva posameznika nič več ne pomikata naokrog po zaslonu, ampak stojita en poleg drugega, se držita za roke ter predstavljata dva človeka v spolnem razmerju. Na ekranu to vidimo tako, da ozadje tistih dveh, ki sta v paru, posivi. 

Prisotnost virusa HIV v populaciji je prikazana z barvo posameznikov. Uporabljene so tri barve: 
- zeleni posamezniki niso okuženi z virusom HIV, 
- modri posamezniki so okuženi z virusom HIV, vendar za svojo okužbo še ne vedo,
- rdeči posamezniki pa so okuženi z virusom HIV in je njihova okužba znana.

Ko kliknemo gumb nastavitve, se nam v desnem okencu prikažejo posamezniki s specifičnimi značajskimi lastnostmi glede na vrednosti petih drsnikov grafičnega vmesnika (pojasnjeno spodaj).

Ko je simulacija enkrat nastavljena, je pripravljena, da jo poženemo s pritiskom na gumb izvajaj. Gumb izvajaj požene simulacijo, ki jo izvaja zvezno, dokler ni gumb izvajaj ponovno pritisnjen (takrat se izvajanje ustavi). Med simulacijo, pričeto na gumb izvajaj, lahko spremembe z drsniki vplivajo na značajske lastnosti celotne populacije. Zato je bolje, da že na začetku nastavimo drsnike in jih med samo simulacijo ne premikamo več. 

Vmesnik modela vsebuje dva monitorja: 
- prvi monitor prikazuje odstotek populacije, ki je okužena z virusom HIV (%okuženih) 
- drugi monitor pa prikazuje, koliko časa je preteklo v času izvajanja modela (leta). V tem modelu vsak časovni korak predstavlja en teden. 

Omenili smo že, da naš model vsebuje pet drsnikov. To so: 

1. Drsnik začetna populacija: Število posameznikov v simulaciji, ki bo predstavljalo celotno opazovano populacijo, nastavimo z drsnikom začetna populacija (posameznikov je lahko od 50 do 500). To mora biti nastavljeno predno je pritisnjen gumb nastavitve. Ko določamo lastnosti populacije, vsem posameznikom določimo značilnosti s pomočjo ostalih štirih drsnikov. 

2. Drsnik povprecna-spolna-aktivnost (nastavimo med 0.0 in 10.0) določa težnjo posameznika, da postane vezan v par (kot smo zapisali zgoraj, so vsi pari spolno aktivni). Ko je drsnik povprečna-spolna-aktivnost nastavljen na 0, nastajanje novih parov ni pričakovano, vendar je še vedno mogoče. Upoštevati moramo, da sta za par potrebna dva posameznika, ki sta se za to svobodno odločila. 

3. Drsnik povprečno-trajanje-zveze (nastavimo med 1.0 in 200.0) določa, koliko tednov bosta dva posameznika ostala v paru. Ponovno je potrebno upoštevati značilnosti obeh v razmerje vključenih posameznikov: razmerje traja samo tako dolgo, dokler eden od obeh posameznikov v paru ne prekine zveze. 

4. Drsnik povprečno-število-uporabnikov-kondoma (nastavimo med 0.0 in 10.0) določa prizadevanje posameznikov v populaciji za varno spolnost (to pomeni, da pri spolnem odnosu uporabljajo kondom). Če posameznik uporablja kondom, je v tem modelu privzeto, da okužba z virusom HIV ni mogoča. Upoštevajte pa, da je ta tendenca (kot tudi ostale) verjetnostna na več nivojih. Npr. če je drsnik povprečno-število-uporabnikov-kondoma nastavljen na 9, potem je povprečna uporaba kondoma pri posamezniku enaka 9 - to pomeni, da nekateri kondom uporabljajo le 8 ali 10-krat, še manj pa jih uporablja le 7 ali 11-krat. Tudi posameznik z vrednostjo uporabe kondoma 9, bi včasih ne uporabljal kondoma (približno v 10% časa). Simulacija uporabe kondoma je še dodatno zapletena zaradi dejstva, da kadar en partner želi uporabljati kondom, medtem ko drugi tega noče, par kondoma ne uporablja. Ta značilnost modela predstavlja dinamiko nekaterih spolnih odnosov, ne pa vseh. Izbira je do neke mere poljubna in uporabnik lahko to značilnost po želji vključi oziroma uporablja ter opazuje, kako je uporaba kondoma pri spolnem odnosu pomembna (ali ne) za povečanje okužb z virusom HIV v populaciji. 

5. Drsnik frekvenca-testiranja (nastavimo med 0.00 in 2.00) je zadnji izmed vseh drsnikov vmesnika. Določa povprečno frekvenco posameznika, da se bo testiral za virus HIV v obdobju enega leta. Nastavljen na 1.0 pomeni, da se bo povprečen človek enkrat letno testiral za virus HIV, medtem ko nastavljen na 0.2 pomeni, da se bo posameznik testiral samo enkrat v petih letih. Pogostost testiranja posameznika za virusom HIV ima pomemben vpliv, saj model predpostavlja, da posamezniki, ki vedo da so okuženi, pri spolnem odnosu vedno uporabljajo kondom, četudi bi bila uporaba kondoma v spolnem odnosu v primeru da bi bili zdravi, drugačna. Ta značilnost modela je ponovno predstavljena kot obnašanje nekaterih posameznikov. Model je bil razvit na ta način zato, da bi jasno pokazal vplive na javno zdravje, ki so povezani z rednim testiranjem in primernim odzivom na poznavanje posameznikovega HIV statusa (okužen, prenašalec ali ni okužen). 

Da bi poznali vpliv drugačnega obnašanja populacije na javno zdravje, bi morali kodo modela relativno enostavno spremeniti. 

V diagramu modela je z grafom pokazano skupno število neokuženih posameznikov (zelena barva), skupno število okuženih posameznikov katerih okužba še ni znana (modra barva) in skupno število okuženih posameznikov katerih okužba je znana (rdeča barva).

Pri modelu lahko nastavimo tudi hitrost izvajanja simulacije. To naredimo s pomočjo drsnika, ki je nad diagramom modela. Če nastavimo modri kvadratek na levo polovico drsnika, bo izvajanje počasno in obratno - bolj ko gremo proti desni, hitrejši bo prikaz okužbe z virusom HIV v populaciji.


STVARI ZA OPAZOVANJE

Npr: Nastavite drsnik začetna-populacija na 300, drsnik povprečna-spolna-aktivnost na 10, drsnik povprečno-trajanje-zveze na 100, ostala dva drsnika pa na 0. Pritisnite gumb nastavitve in nato gumb izvajaj. Sedaj opazujte, kaj se dogaja v populaciji. Zapomnite si, da ko dva posameznika postaneta par, njuno ozadje posivi. Ti pari predstavljajo dva posameznika, ki imata spolne odnose. Tisti posamezniki, ki se še vedno prosto gibljejo po zaslonu (in njihovo ozadje ni obarvano sivo), nimajo partnerjev, zato tudi nimajo spolnih odnosov. Ker smo nastavili drsnik povprečno-trajanje-zveze na 100, nam to pomeni, da sta dva posameznika v paru spolno aktivna. Naš model pa ne dovoljuje varanja, zato je zveza med njima monogamna, kar pomeni, da si bosta zvesta 100 tednov (to je približno 2 leti), nakar se bosta razšla in si morebiti poiskala novega partnerja. 

Sedaj ustavite simulacijo (pritisnete gumb izvajaj). Drsnik povprečna-spolna-aktivnost nastavite na 0, pritisnite gumb nastavitve in ponovno poženite simulacijo s pritiskom na gumb izvajaj. Opazili boste, da se v tem primeru virus HIV med posamezniki ne širi. To je posledica nastavitve drsnika povprečna-spolna-aktivnost, saj nastavljen na 0 pomeni, da posamezniki niso spolno aktivni. In ker naš model predpostavlja, da se virus HIV prenaša samo s spolnimi odnosi, okužbe niso mogoče. 

Poglejmo še eno zanimivost. Nastavite drsnik povprečna-spolna-aktivnost na 10.0 in drsnik povprečno-trajanje-zveze na 1. Poženite simulacijo. Ker imamo posameznike, ki so redko spolno aktivni in je uporaba kondoma pri njih zelo visoka, bi predpostavili, da se virus HIV med populacijo ne bo širil. Dobro poglejte simulacijo in opazili boste, da se modri posamezniki zelo hitro obarvajo rdeče. To je posledica dveh stvari: prvič - nekateri posamezniki so bili že dolgo časa okuženi, pa se svoje okužbe niso zavedali, dokler se niso na njihovem zdravju pokazali simptomi okužbe, ki so jih pripravili do tega, da so se šli testirat; drugič - ker so se posamezniki sami odločili za testiranje za virusom HIV. Drsnik frekvenca-testiranja nastavljen na 1.0 pomeni, da se bo povprečen človek enkrat letno testiral za virusom HIV. Testirali so se tudi tisti, ki so zdravi, vendar se njihova barva (zeleni) ni spremenila, saj niso okuženi s tem smrtnonosnim virusom.  

Sedaj spremenite drsnike (ne ustavljajte simulacije) in sicer: drsnik povprečna-spolna-aktivnost na 10, drsnik povprečno-trajanje-zveze na 1, drsnik povprečno-število-uporabnikov-kondoma na 0 in drsnik frekvenca-testiranja na 0. Kaj opazite ? Kako je to mogoče ? Če dobro pogledate model opazite, da se procent okuženih ni povečal, čeprav bi to pričakovali. Razlog je ta, da naš model predpostavlja, da imajo okuženi posamezniki (rdeči) varno spolnost, kar pomeni, da pri spolnem odnosu uporabljajo kondom. Zato se virus HIV ne širi na zdrave posameznike. 


STVARI ZA POSKUSITI

Nastavite drsnike na različne vrednosti in opazujte, kaj se dogaja v posameznem primeru. Poskusite tako, da vsakič spremenite le en drsnik, saj boste tako lažje opazili vpliv posamezne spremenljivke na celotno populacijo. Npr. da bi ugotovili kakšen vpliv na okuženost z virusom HIV v populaciji ima trajanje partnerske zveze, poglejte štiri možnosti - drsnik povprečno-trajanje-zveze nastavite prvič na 1, drugič na 2, tretjič na 10 in nato na 50. Kako posamezna nastavitev vpliva na rast virusa HIV v populaciji ? Ali se ugotovitve ujemajo z vašo predstavo o tem ?

Ali so vplivi posameznih drsnikov odvisni od nastavitev ostalih drsnikov ? Npr. če visoka nastavitev drsnika povprečna-spolna-aktivnost (ostali drsniki so nastavljeni na najnižjo vrednost) vpliva na povečanje okužb z virusom HIV v populaciji, ali to velja tudi, če so ostali drsniki nastavljeni na 10 ?

Na takšen način lahko preverite vsa svoja predvidevanja, kako spolno obnašanje posameznika vpliva na zdravje celotne populacije. 


RAZŠIRITEV MODELA

Omenili smo že, da naš model predvideva, da imajo vsi pari spolne odnose, da se partnerji ne varajo in da vsi okuženi posamezniki pri spolnem odnosu uporabljajo kondom. Vendar v resničnem življenju ni vedno tako. 

Zato bi lahko simulirali kakšne drugačne okoliščine, kot npr: 
- za posameznika, ki sta v paru, ni nujno, da imata spolne odnose (te bi pobarvali z neko novo barvo)
- naš model se ne ozira na spol posameznika - lahko bi razširili model tako, da bi dodali spol posameznikom in tako naredili model bolj realističen
- v resničnem življenju žal ni vedno tako, da posamezniki, ki so okuženi z virusom HIV, uporabljajo kondom pri spolnem odnosu - zato bi model spremenili tako, da bi dodali še to spremenljivko in tako prispevali k ozaveščanju nevarnosti okužbe z virusom HIV
- naš model tudi predvideva, da je uporaba kondoma 100% zanesljiva - lahko bi naredili drsnik, kjer bi uporabnik nastavil to zanesljivost in opazovali situacijo v takšnem primeru
- možnosti je še veliko .....


ZAHVALE IN REFERENCE 

Posebna zahvala gre g. Steve Longenecker-ju za razvoj modela. 
Za sklicevanje na ta model v akademskih krogih, prosimo uporabite: Wilensky, U. (1998). NetLogo AIDS model. http://ccl.northwestern.edu/netlogo/models/AIDS. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL. 
Za ostale publikacije, prosimo uporabite: Copyright 1998 by Uri Wilensky. Vse pravice pridržane. Poglejte http://ccl.northwestern.edu/netlogo/models/AIDS za pravice uporabe. 
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

person lefty
false
0
Circle -7500403 true true 170 5 80
Polygon -7500403 true true 165 90 180 195 150 285 165 300 195 300 210 225 225 300 255 300 270 285 240 195 255 90
Rectangle -7500403 true true 187 79 232 94
Polygon -7500403 true true 255 90 300 150 285 180 225 105
Polygon -7500403 true true 165 90 120 150 135 180 195 105

person righty
false
0
Circle -7500403 true true 50 5 80
Polygon -7500403 true true 45 90 60 195 30 285 45 300 75 300 90 225 105 300 135 300 150 285 120 195 135 90
Rectangle -7500403 true true 67 79 112 94
Polygon -7500403 true true 135 90 180 150 165 180 105 105
Polygon -7500403 true true 45 90 0 150 15 180 75 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@