globals [
  initial-trees   ;; how many trees (green patches) we started with
  burned-trees    ;; how many have burned so far
]

breeds [
  fires    ;; bright red turtles -- the leading edge of the fire
  embers   ;; turtles gradually fading from red to near black
]

to setup
  ca
  ;; make some green trees, leaving edges blank so
  ;; the fire can't wrap around the edges of the screen
  ask patches with [abs pxcor < screen-edge-x and
                    abs pycor < screen-edge-y]
    [ if (random-float 100) < gostota 
        [ set pcolor green ] ]
  ;; make a column of burning trees
  ask patches with [pxcor = (- screen-edge-x)]
    [ ignite ]
  ;; set tree counts
  set initial-trees count patches with [pcolor = green]
  set burned-trees 0
end

to go
  if not any? turtles
    [ stop ]
  ask fires
    [ ;; use without-interruption to prevent the same patch
      ;; from igniting multiple times
      without-interruption
        [ ask neighbors4 with [pcolor = green]
            [ ignite ]
          set breed embers ] ]
  fade-embers
end

to ignite  ;; patch procedure
  sprout 1
    [ set breed fires
      set color red ]
  set pcolor black
  set burned-trees burned-trees + 1
end

to fade-embers
  ask embers
    [ set color color - 0.3  ;; make red darker
      if color < red - 4     ;; are we almost at black?
        [ stamp color
          die ] ]
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2003.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Fire model.
; http://ccl.northwestern.edu/netlogo/models/Fire.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/Fire
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
200
10
612
443
100
100
2.0
0
10
1
1
1

CC-WINDOW
5
252
199
443
Command Center

MONITOR
43
125
164
174
procent požganega
(burned-trees / initial-trees)\n* 100
1
1

SLIDER
5
82
190
115
gostota
gostota
0.0
99.0
57.0
1.0
1
%

BUTTON
106
35
175
71
začni
go
T
1
T
OBSERVER
NIL

BUTTON
26
35
98
71
nastavi
setup
NIL
1
T
OBSERVER
T

@#$#@#$#@
KAJ JE TO?
-----------

Model simulira širjenje ognja skozi gozd. Ogenj se začne širiti iz levega kota gozda in se širi po bljižnjih drevesih. Širi se v štirih smereh: sever, jug, vzhod, zahod.

V tem modelu ni vključen veter. Zato mora imeti ogenj na svoji poti drevesa, da se lahko širi. Zato se ogenj ne more širiti po nepogozdovanem območju. Tako območje blokira napredovanje ognja, v njegovem širjenju.

Možnost da ogenj doseže desni rob gozda je odvisna od gostote dreves v gozdu.


KAKO UPORABLJAMO 
----------------

Klikni na gumb NASTAVI postaviš vse parametre na oknu. S tem nastaviš drevesa (zeleno na zaslonu) in ogenj (rdečo na zaslonu).

Klikni na gumb ZAČNI, da pričneš z simulacijo.

Drsnik GOSTOTA nadzoruje poraščenost gozda. (Opomba: premik drsnika GOSTOTA, se upošteva šele ob naslednjem kliku na gumb NASTAVI.)


ZANIMIVO
---------

Nastavi gostoto gozda na 55%. Pri teh nastavitvah skoraj ni možnosti, da bi ogenj dosegel desni rob gozda. Nastavi gostoto gozda na 70%. Pri teh nastavitvah je skoraj gotovo, da bo ogenj prišel na desni rob. Pri 59% ima ogenj 50/50 možnosti, da pride na desno stran gozda.

Črna obroba okoli gozda, preprečuje ognju, da se širi izven zaslona.

Vsaka želvica, ki predstavlja košček ognja se rodi in umre z vsakim premikom. Zato se nobena želva ne premika po zaslonu. Vsako drevo lahko gori ali pa ne gori. Efekt (premikajočega ognja) je ustvarjen z agenti, čeprav ni občuteno z agenti. To je podobno optični iluziji.


RAZŠIRITEV MODELA
------------------

Kaj pa če bi se lahko ogenj širil v osmih smereh (tudi po diagonalah)? Da to dosežemo uporabimo "neighbors" namesto "neighbors4" (v prodesurnem oknu->procedura GO). Kako bi to povečalo možnost ognja, da doseže desno stran? V tem novem modelu, kakšna je "kritična gostota" dreves da ogenj že doseže desni rob?

Dodaj veter, da bo lahko ogenj premagoval (preskakoval) daljše razdalije v posameznih smereh.


NETLOGO PRIHODNOSTI
---------------------

Nezgorjena drevesa so predstavljena z zeleno potjo, požgana drevesa pa z želvicami.
Uporabljene so dve vrsti želvic, "ogenj" in "ostanki". Ko je drevo ujeto v ogenj, se ustvari nova želva ogenj, ogenj postane pogorišče v naslednjem koraku. Opazuj kako program stopnjuje črnino pogorišča, da doseže efekt zgorevanja.

Primitiv "neighbors4" je uporabljen za širjenje ognja.

Lahko napišeš model brez želvic, s samo sledjo ognja. Napisan tako, bi model tekel bolj počasi, saj bi bile vse poti zmeraj aktivne. Z uporabo želvic je bolj enostavno doseči omejitev aktivnosti modela zgolj na notranjost ograjenega gozda.

Poglej stavka "CA 1D Rule 30" in "CA 1D Rule 30 Turtle" kot primera modela oboje z in brez želvice.


PODOBNI MODELI
----------------

Percolation, Rumor Mill


ZASLUGE IN REFERENCE
---------------------

Ta model je nastal v v MIT Media Lab. Poglej Resnick, M. (1994) "Turtles, Termites and Traffic Jams: Explorations in Massively Parallel Microworlds." Cambridge, Ma: MIT Press. Adapted to StarLogoT, 1997, kot del Connected Mathematics Project. Leta 2000 je bil prilagojen NetLogo, kot del Participatory Simulations Project. Posodobljen leta 2003.

Za naslavljanje modela v akademskih publikacijah uporabi: Wilensky, U. (1998).  NetLogo Fire model. http://ccl.northwestern.edu/netlogo/models/Fire. Center za Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Za druge publikacije uporabi: Copyright 1998 by Uri Wilensky.  Vse pravice so pridržane. Poglej http://ccl.northwestern.edu/netlogo/models/Fire za pogoje uporabe.

Model je poslovenil Pavel Makovec, dne 18. 9. 2005.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

@#$#@#$#@
NetLogo 2.0.2
@#$#@#$#@
set density 60
setup
repeat 180 [ go ]
@#$#@#$#@
@#$#@#$#@