globals
[
  text        ;; besedilo, ki se bo izpisalo
  left-edge   ;; pxcor koordinata najbolj levega stolpca, kamor gredo lahko črke
  right-edge  ;; ditto za najbolj desnega
]

turtles-own
[
  word-length ;; dolžina besede v kateri se nahaja želva
  num-word    ;; številka želvine besede v besedilu
  leader      ;; želva z znakom pred tem želvjim znakom
  new-line?   ;; ali začnemo novo vrstico ali ne
]

;; nastavitev spremenljivk in Prikaza
to nastavitev
  ca
  set text "These are the times that try men's souls. " +
           ;; naslednja dva stavka vsebujeta vseh 26 črk abecede,vsak!(which makes them
           ;; (kar ju naredi zelo dobra za preizkušanje pisalnih strojev)
           "The quick brown fox jumped over the lazy dog. " +
           "Pack my box with five dozen liquor jugs."
  draw-margins
  ;; naredi želvo "nevidno", z uporabo oblike brez vsebine
  ;; ne moremo uporabitie  hide-turtle ker želimo videti željvino označbo
  set-default-shape turtles "blank"
  ;; ustvari zadostno število želv, po eno za vsak znak v besedilu
  cct (length text)
  [
    set word-length 0
    set leader nobody
    set new-line? false
    raztresi
  ]
  setup-letters
end

to raztresi  ;; želvja procedura, določijo se naključne koordinate x in y
  setxy random-xcor random-ycor
end

to draw-margins
  ask patches
    [ ifelse (pxcor = levi-rob + min-pxcor) or
             (pxcor = max-pxcor - desni-rob)
        [ set pcolor red ]
        [ set pcolor black ] ]
end

;; dodeli želvam črke, določi kdo jih vodi,
;; in nastavi dolžino posamezne besede
to setup-letters
  let remaining-text text
  let word-count 1
  let prev-letter nobody

  ask turtles
  [
    without-interruption
    [
      set label first remaining-text
      set leader prev-letter
      set num-word word-count
      if label = " "
      [
        set word-count word-count + 2
        set num-word num-word + 1
      ]
      set remaining-text but-first remaining-text
      set prev-letter self
    ]
  ]

  let index 1
  repeat word-count
  [
    let turtles-in-word turtles with [num-word = index]
    ask turtles-in-word
      [ set word-length count turtles-in-word ]
    set index index + 1
  ]
end

;; glavna procedura katere ime je Začni, gumb
to zacni
  update-margins
  ask turtles
  [
    set new-line? false
    pick-heading  ;; izbere naslov prave zaplate
    ;; če želva ni zadovoljna z mestom, kjer se nahaja, glede na razdaljo 
    ;; do vodnika, se malo premakne naprej
    ifelse happy?
      [ setxy pxcor pycor ]  ;; premik v središče zaplate
      [ fd 0.5 ]
  ]
end

;; posodobi levo-robne in desno-robne spremanljivke, da se ujemajo z robnimi
;; drsniki in ponovno nariše robove,če je potrebno
to update-margins
  if left-edge != levi-rob + min-pxcor + 1
    [ set left-edge levi-rob + min-pxcor + 1
      draw-margins ]
  if right-edge != max-pxcor - desni-rob - 1
    [ set right-edge max-pxcor - desni-rob - 1
      draw-margins ]
end

;; nastavi želvji naslov na primerno zaplato
to pick-heading
  ifelse leader = nobody
    ;; prva črka gre na zgornjo skrajno levo zaplato
    [ face patch left-edge max-pycor ]
    ;; ostale zaplate se gibajo proti zaplati, ki je desno od vodnikove
    [
      let p value-from leader [patch-at 1 0]
      if p != nobody
      [ face p ]
      ifelse right-edge - left-edge < word-length
      [
        ;; če je naša beseda predolga za širino bededila,
        ;; preveri, če se zaplata desno od vodnika nahaja na robu ali sega čez
        ;; desni rob
        if pxcor-of leader >= right-edge
        [
          ;; če je, spremeni naslov v začetek nove vrstice
          set new-line? true
          face patch left-edge new-line-pycor
        ]
      ]
      [
        ;; če je naša beseda dovolj kratka, da še gre v eno vrstico, ampak 
        ;; trenutno ni dovolj prostora v tej vrstici, poskusi obiti besedo.
        ;; to pomeni, če se želva nahaja na začetku besede in je le-ta predolga
        ;; za zaključitev v vrstici, glede na začetno točko besede vodnika,
        ;; se pomakne v novo vrstico.        
        if (num-word != num-word-of leader) and
           (pxcor-of leader + word-length >= right-edge)
        [
          ;; če je, spremeni naslov v začetek nove vrstice
          set new-line? true
          face patch left-edge new-line-pycor
        ]
      ]
  ]
end

;; vrne pycor (y koordinate)nove vrstice, kamor mora želva,
;; temelji na mestu njenega vodnika in širini besedila
to-report new-line-pycor  ;; želvja procedura za določanje nove vrstice
  ifelse abs (pycor-of leader - razmik-vrstic) > max-pycor
    [ report pycor-of leader ]
    [ report pycor-of leader - razmik-vrstic]
end

;; vrne true če je želva zadovoljna s trenutnim mestom
to-report happy?  ;; želvja procedura
  if leader = nobody  ;; če je želva prva črka...
    ;; ...ali je v zgornji skrajno levi zaplati?  
    [ report (pxcor = left-edge) and (pycor = max-pycor) ]
  ifelse new-line?  ;; želimo začeti novo vrstico?
    ;; ali se želva nahaja na začetku naslednje vrstice?
    [ report (pxcor = left-edge) and (pycor = new-line-pycor) ]
      ;; ali se želva nahaja na zaplati desno od svojega vodnika?
    [ report patch-at -1 0 = value-from leader [patch-here] ]
end


; *** Model Netloga - opozorilo glede avtorskih pravic ***
;
; Ta model je bil narejen kot del projekta : POVEZANA MATEMATIKA:
; SMISEL KOMPLEKSNEGA FENOMENA SKOZI GRADNJO OBJEKTA-OSNOVA PARALELNEGA 
; MODELA (OBPML). Projekt hvalezno prizna podporo 
; Narodne znanstvene ustanove ( Prosnje za program napredne 
; tehnologije) -- dovoljenje st. RED #9552950 in REC #9632612.
;
; Avtorska pravica 1998 : Uri Wilensky. Vse pravice pridržane.
;
; Dovoljenje za uporabo, prilagoditev ali ponovno distribucijo modela je s tem dovoljena
; pod pogojem da sta upostevana spodnja pogoja:
; a) to opozorilo avtorske pravice je prilozeno
; b) ta model ne bo ponovno narejen za dobicek brez dovoljenja Uri Wilensky.
; Pri ponovni distribuciji modela za dobicek navezi stik z Uri Wilensky.
;
; Ta model je bil spremenjen v NetLogo kot del projekta:
; SODELOVALNO SIMULIRANJE: OMREZNO SESTAVLJEN NACRT ZA UCENJA V 
; RAZREDIH in/ali INTEGRIRANI SIMULACIJi IN MODELNEM OKOLJU.
; Projekt hvalezno prizna podporo 
; Narodne znanstvene ustanove (program REPP & ROLE programi) 
;-- dovoljenje st. REC #9814682 in REC-0126227.
; Spremenjen iz StartLogot-a v NetLogo, 2001.
;
; Za sklicevanje modela v akademski publikaciji, prosim, uporabite:
; Wilensky, U. (1998).  NetLogo model PohajkajočeSEčrke.
; http://ccl.northwestern.edu/netlogo/models/WanderingLetters.
; Center za povezano ucenje in modeli zgrajeni na osnovi racunalnika
; Northwestern University, Evanston, IL.
;
; V drugih publikacijah prosim, uporabite:
; Avtorska pravica, 1998, Uri Wilensky.  Vse pravice pridrzane. Oglej si
; http://ccl.northwestern.edu/netlogo/models/WanderingLetters
; za pogoje uporabe.
;
; *** Konec opozorila avtorskih pravic za ta model ***
@#$#@#$#@
GRAPHICS-WINDOW
260
12
647
420
14
14
13.0
1
10
1
1
1
0
0
0
1
-14
14
-14
14

CC-WINDOW
5
434
656
529
Command Center
0

SLIDER
34
126
206
159
razmik-vrstic
razmik-vrstic
1
3
2
1
1
NIL

BUTTON
60
82
183
115
Raztresi črke
raztresi
NIL
1
T
TURTLE
T
NIL

BUTTON
138
36
204
69
Začni
zacni
T
1
T
OBSERVER
T
NIL

BUTTON
29
36
121
69
Nastavitev
nastavitev
NIL
1
T
OBSERVER
T
NIL

SLIDER
34
182
206
215
levi-rob
levi-rob
0
12
2
1
1
NIL

SLIDER
35
236
207
269
desni-rob
desni-rob
0
12
9
1
1
NIL

@#$#@#$#@
KAJ JE TO?
-----------
Ta model ilustrira kako zgraditi besedni predelovalec v katerem vsaka črka nastopa samostojno. Vsaki črki je znano le, katera črka se bo nahajala pred njo in kako dolga bo beseda. Ko se črke in robovi premaknejo, črke same poiščejo pot do njihovega pravega mesta.  


KAKO DELUJE
------------
Vsaka črka opazuje spremembi robov in svojo neusklajenost s svojim "vodnikom", ki je  črka, ki se v besedilu nahaja pred njo. Če se črka ne nahaja na svojem pravem mestu, relativno glede na svojega vodnika, naredi korak v vodnikovi smeri.


NAVODILA ZA UPORABO
-------------
NASTAVITEV nastavi robove in nekatere primere stavkov za besedilo v prvotno stanje.

ZAČNI začne in ustavi simulacijo.

Drsnika LEVI-ROB in DESNI-ROB omogočata nastavljanje robov. Te drsnike lahko premikaš medtem ko je ZAČNI vklopljen, črke pa se bodo prilagodile razporku.

RAZTRESI ČRKE nalkjučno raztrese črke po zaslonu. Gumb lahko vklopiš tudi ko se ZAČNI izvaja.

RAZMIK-VRSTIC določa razmik med vrsticami.


STVARI ZA OPAZOVATI
----------------
Kako črke vedo, kam morajo iti? V čem se to obnašanje črk razlikuje od obnašanja črk v običajnem besednem predelovalcu?


STVARI; KI JIH JE POTREBNO POISKUSITI
-------------
Ko je ZAČNI vklopljen poskusi:
--Premikati drsnika robov
--Spreminjati razmik
--Pritiskaj gumb za raztresanje črk
--Kombinirati vse troje našteto


NADALJEVANJE MODELA
-------------------

Lahko razširiš model tako, da bo lahko uporabnik vnesel njegovo/njeno sporočilo? Morda bi poizkusil z uporabo User-input primitive.

Včasih se bo na začetku nove vrstice pojavil presledek. Poskusi model popraviti tako, da bodo presledki na koncu vrstic ignorirani.


ZNAČILNOSTI NETLOGA 
----------------
Bodi pozoren na uporabo brezizrazne oblike, ki jo ima želva, in ki je nevidna razen za označbo.


ZAUPANJE IN PRIPOROČILA
----------------------
Ta model je osnovan na Smalltalk programu enakega imena, ki ga je razvil Ted
Kaehler iz Disney Interactive.


Za sklicevanje na model v člankih, prosim uporabite:  Wilensky, U. (1998).  NetLogo Wandering Letters model.  http://ccl.northwestern.edu/netlogo/models/WanderingLetters.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Za druge objave, prosim uporabite:  Copyright 1998 Uri Wilensky.  Vse pravice pridržane.  Glejte http://ccl.northwestern.edu/netlogo/models/WanderingLetters za pogoje uporabe.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

blank
false
0

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.1
@#$#@#$#@
setup
ask turtles [ scatter ]
repeat 50 [ go ]
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@