breed [ muscle-fibers muscle-fiber ]

muscle-fibers-own [
  fiber-size   ;; razlicno od "velikosti" built-in, ker uporablja drugacne enote
  max-size
]

patches-own [
  anabolic-hormone  ;; hormon za gradnjo misicnih vlaken
  catabolic-hormone ;; hormon za rusenje misicnih vlaken
]

globals [
  dan  ;; casovna enota za eno iteracijo
  muscle-mass  ;; shranjuje vsoto velikosti za muscle-fiber (misicna vlakna)
  ;; omejitev hormonov za zagotovitev realisticnega okolja
  anabolic-hormone-max
  anabolic-hormone-min
  catabolic-hormone-max
  catabolic-hormone-min
  ;; stopnja razsirjanja hormonov od enega vlakna do drugih
  hormone-diffuse-rate
]

to nastavi
  ca
  set-default-shape muscle-fibers "circle"
  initialize-hormones
  create-muscle-fibers
  set muscle-mass sum values-from muscle-fibers [fiber-size]
  set dan 0
  do-plotting
end

to initialize-hormones
  ;; konstante, ki so izbrane pri postavitvi modela za razvoj misice
  ;; z realno vrednostjo
  set hormone-diffuse-rate 0.75
  ask patches [
    set anabolic-hormone-max 200
    set catabolic-hormone-max 250
    set anabolic-hormone-min 50
    set catabolic-hormone-min 52
    set anabolic-hormone 50
    set catabolic-hormone 52
  ]
  regulate-hormones
end

to create-muscle-fibers
  ask patches [
    sprout-muscle-fibers 1 [
      set max-size 4
      ;; ustvari normalizirano razporeditev maksimalne velikosti misicnih vlaken
      ;; s srednjo odvisnostjo % pocasnega trzanja vlaken.
      repeat 20  [
        if random-float 100 > %-pocasnega-krcenja-vlaken [
          set max-size max-size + 1
        ]
      ]
      ;; preskrbi nenenotne zacetne velikosti za razlicne rezultate, vsak je drugacen
      set fiber-size (0.2 + random-float 0.4) * max-size
      regulate-muscle-fibers
    ]
  ]
end

to izvajaj
  set dan (dan + 1)
  ;; ...bodite pozorni na uporabo primitiva LOG v procedurah ...
  ;; ...za simulacijo naravnih sistemskih tendenc, klicanih spodaj,...
  ;; ...za vedno manjso prilagoditev vsake dodatne enote neke bioloske substance
  perform-daily-activity
  if dviganje? and (dan mod stevilo-dnevov-med-treningi = 0) [
    lift-weights
  ]
  sleep
  regulate-hormones
  develop-muscle
  set muscle-mass sum values-from muscle-fibers [fiber-size]
  do-plotting
end

to perform-daily-activity
  ;; simulacija hormonske učinkovitosti zivljenjskega stila
  ;; aktivnosti kot so gledanje televizije in sluzba
  ask muscle-fibers [
    set catabolic-hormone catabolic-hormone + 2.0 * (log fiber-size 10)
    set anabolic-hormone anabolic-hormone + 2.5 * (log fiber-size 10)
  ]
end

to lift-weights
  ;; simulacija hormonske ucinkoviteosti treninga z utezmi
  ask muscle-fibers [
    if( random-float 1.0 < intenziteta / 100 * intenziteta / 100 ) [
      set anabolic-hormone anabolic-hormone + (log fiber-size 10) * 55
      set catabolic-hormone catabolic-hormone + (log fiber-size 10) * 44
    ]
  ]
end

to sleep
  ;; simuacija hormonske ucinkovitosti spanja
  ask patches [
    set catabolic-hormone catabolic-hormone - 0.5 * (log catabolic-hormone 10) * ure-spanja
    set anabolic-hormone anabolic-hormone - 0.48 * (log anabolic-hormone 10) * ure-spanja
  ]
end

to develop-muscle
  ask muscle-fibers [
    grow
    regulate-muscle-fibers
  ]
end

to grow  ;; zelvja procedura
  ;; katabolicni hormoni morajo pripraviti vlakna za rast preden... 
  ;; ...anabilicni hormoni dodajajo maso na vlakna
  set fiber-size (fiber-size - 0.20 * (log catabolic-hormone 10))
  set fiber-size (fiber-size + 0.20 * min (list (log anabolic-hormone 10)
                                                (1.05 * log catabolic-hormone 10)))
end

to regulate-muscle-fibers ;;zelvja procedura
  ;; simulira naravne telesne meje na minimalno in maksimalno velikost vlakna
  if (fiber-size  < 1) [ set fiber-size 1 ]
  if (fiber-size > max-size) [ set fiber-size max-size ]
  set color scale-color red fiber-size (-0.5 * max-size) (3 * max-size)
  ;; osnova vidne velikosti zelve na fiber-size
  set size max list 0.2 (min list 1 (fiber-size / 20))
end

to regulate-hormones ;; procedura sosedov
  ;; hormoni se širijo k sosednjim vlaknom
  diffuse anabolic-hormone hormone-diffuse-rate
  diffuse catabolic-hormone hormone-diffuse-rate
  ;; ce je prevec ali premalo hormonov na podrocju, ...
  ;; ... bo telo zavzeto poskusalo vzpostaviti ravnotezje
  ask patches [
    set anabolic-hormone min (list anabolic-hormone anabolic-hormone-max)
    set anabolic-hormone max (list anabolic-hormone anabolic-hormone-min)
    set catabolic-hormone min (list catabolic-hormone catabolic-hormone-max)
    set catabolic-hormone max (list catabolic-hormone catabolic-hormone-min)
    ;; barva soseda bazira na hormonski koncentraciji
    set pcolor rgb (catabolic-hormone / catabolic-hormone-max)
                   (anabolic-hormone / anabolic-hormone-max)
                   0
  ]
end

to do-plotting
  set-current-plot "Misicna rast"
  set-current-plot-pen "misica"
  plot muscle-mass / 100

  set-current-plot "Hormoni"
  set-current-plot-pen "anabolicni"
  plot mean values-from patches [anabolic-hormone]
  set-current-plot-pen "katabolicni"
  plot mean values-from patches [catabolic-hormone]
end


; *** NetLogo 3.1.4 Model Copyright Notice ***
;
; This model was created as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) --
; grant numbers REC #9814682 and REC-0126227.
;
; Copyright 2002 by Uri Wilensky.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2002).  NetLogo Muscle Development model.
; http://ccl.northwestern.edu/netlogo/models/MuscleDevelopment.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 2002 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/MuscleDevelopment
; for terms of use.
;
; *** End of NetLogo 3.1.4 Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
329
11
730
433
8
8
23.0
1
10
1
1
1
0
1
1
1
-8
8
-8
8

CC-WINDOW
5
519
739
614
Command Center
0

BUTTON
43
22
117
56
Nastavi
nastavi
NIL
1
T
OBSERVER
T
NIL

SLIDER
5
139
221
172
Stevilo-dnevov-med-treningi
Stevilo-dnevov-med-treningi
1
30
5
1
1
dni

SLIDER
5
106
221
139
Ure-spanja
Ure-spanja
0.0
12.0
8.0
0.5
1
ur

PLOT
5
209
322
354
Misicna rast
Cas
Misicna masa
0.0
60.0
0.0
20.0
true
false
PENS
"Misica" 1.0 0 -2674135 true

PLOT
5
354
321
505
Hormoni
Cas
Hormoni
0.0
60.0
0.0
30.0
true
true
PENS
"Anabolicni" 1.0 0 -16777216 true
"Katabolicni" 1.0 0 -1184463 true

MONITOR
227
157
322
206
Dan
dan
1
1

SLIDER
5
73
221
106
Intenziteta
Intenziteta
50
100
90
1
1
NIL

BUTTON
127
22
197
56
Izvajaj
izvajaj
T
1
T
OBSERVER
T
NIL

SWITCH
226
73
322
106
Dviganje?
Dviganje?
0
1
-1000

SLIDER
5
172
221
205
%-pocasnega-krcenja-vlaken
%-pocasnega-krcenja-vlaken
0.0
100.0
50.0
1.0
1
NIL

@#$#@#$#@
KAJ JE?
-----------
To je model fiziološke vadbe. Njegov namen je, da pomaga razumeti faktorje, ki so vpleteni v proizvidnjo primernih hormonskih ravnotežij, ta pa razvijajo mišico ob dvigovanju uteži. Ti faktorji vsebujejo:

Pogostost: 
Če želimo videti napredek pri izboljšanju mišične mase, mora biti pogostost dvigovanja uteži primerna. Prepogosto dvigovanje uteži ne dopušča časa za obnovo mišice, ki naredi mišico močnejšo. Če pa je pogostost dvigovanja uteži premajhna, mišica ne bo dovolj spodbujena, da bi dosegli dolgoročen napredek pri njeni rasti.

Spanec: 
Telo večino svojega obnavljanja izvrši med spanjem. Če ne spimo dovolj, telesu ne priskrbimo dovolj priložnosti za obnovo in tako je otežen tudi napredek pri rasti mišice.

Intenzivnost: 
Intenziteta vadbe vpliva na učinkovitost okrepitve vseh mišičnih vlaken. Večje je število okrepljenih vlaken, večja je rast dražljaja, s predpostavko, da je mišici zagotovljeno primerno obnavljanje.

Dednost: 
Razmerje med počasnim in hitrim krčenjem mišičnega vlakna igra pomembno vlogo pri sposobnosti razvijanja posmezne mišice. Nekdo, ki ima večino vlaken s karakteristiko počasnega krčenja, bo imel visoko stopnjo vzdržljivosti, vendar možnost razviti le zmerno mišično maso. Nekdo, ki ima večino vlaken s karakteristiko hitrega krčenja, bo imel možnost razviti precejšnjo mišično maso, vendar nizko stopnjo vzdržljivosti. 

Dieta: 
Skromna dieta lahko prepreči rast mišic. V tem modelu predpostavimo popolno dieto.

Vseh pet faktorjev moramo razumeti in jih medsebojno uskladiti z namenom da dosežemo optimalni mišični razvoj. Pravilna kombinacija je močno odvisna od posameznika in njegovega edinstvenega trenutnega stanja, ki se bo sčasoma spremenjalo.


KAKO DELUJE?
------------

Nazadnje je učinkovitost treninga rezultat hormonskih reakcij v telesu. Hormone, ki so bistveni za mišični razvoj, lahko ločimo na dva razreda: katabolični hormoni in anabolični hormoni. Katabolični hormoni poškodujejo mišično vlakno in ga s tem pripravijo na ponovno okrepitev s pomočjo anaboličnih hormonov. Opomba: Katabolični hormoni igrajo življensko pomembno vlogo, saj se morajo mišična vlakna najprej porušiti, da se lahko potem zgradijo nazaj.

Ta model poskuša simulirati učinkovitost treninga s pomočjo prečnega prereza mišice na ravni mišičnih vlaken. Ko opazovalec aktivira mišično vlakno v času treninga, vlakno izpusti kemični signal, ki pošlje val hormonov na lokacijo vlakna. Ti hormoni vplivajo na razvoj vlakna, kot je opisano zgoraj, in se čez čas razpršijo.
 
Krogi predstavljajo mišična vlakna. Ozadje, ki se pojavi, predstavlja celično tekočino, ki vsebuje anabolične in katabolične hormone. Bolj svetla kot je zelena barva, bolj anabolično (grajenje mišice) je okolje. Bolj svetla kot je rumena barva, bolj katabolično (uničevanje mišice) je okolje.

KAKO GA UPORABLJAMO?
-------------
Gumbi:
NASTAVI: Nastavi model na začetek
IZVAJAJ: Sproži izvajanje algoritma

Stikala:
DVIGANJE?: Določi ali oseba aktivno dviguje uteži ali ne.

Drsniki:
INTENZITETA: Kako intenzivno dvigovalec trenira. Večja je intenziteta, večje je število izčrpanih mišičnih vlaken ob vsaki vadbeni seriji.
URE-SPANJA: Količina spanca osebe vpliva na to, kako hitro telo porazdeli hormone.
STEVILO-DNEVOV-MED-TRENINGI: Pogostost vadbe učinkuje na čas, ki ga telo potrebuje za obnovitev in ponovno vzpostavitev ravnotežja od zadjega treninga.
%-POCASNEGA-KRCENJA-VLAKEN: Kolikšna je verjetnost da ima vsako vlakno karakteristiko počasnega trzanja.

Grafi:
MISICNA RAST (MISICNA MASA/CAS): Vsota debelin vseh vlaken (mišična masa) v odvisnosti od časa.
HORMONI (HORMONI/CAS): Povprečna hormonska prostornina blizu vsakega vlakna v odvisnosti od časa.

POSKUSITE
----------------
Koraki 1 do 3 naj tečejo z drsnikom %-POCASNEGA-KRCENJA-VALKEN nastavljenim na vrednost 50.

1. Zaženite model z njegovimi privzetimi nastavitvami. Kaj se sčasoma zgodi s količino mišične mase? Zakaj?

2. Pretreniranost se pojavi, ko telesu ni omogočena popolna obnovitev od zadnjega treninga pred naslednjim treningom. To povzroči zaustavitev mišičnega razvoja in v ekstremnih primerih celo izgubo mišičevja. Kakšne okoliščine lahko pripeljejo do pretreniranosti? Kakšna je najboljša pot do okrevanja od pretreniranosti? Na kakšne načine se lahko izognemo pretreniranosti?

3. Veliko ljudi se odloči za trening z dvigovanjem uteži, da bi zgradili maksimalno količino mišičevja, ki so je sposobni. Za dosego tega cilja poiščite najboljšo metodo. Kako se mora sčasoma sprememniti? Zakaj je pomembno poznati trenutno raven kondicije pri izbiri programa treninga?

4. Vprašanje, ki je redko zastavljeno v običajnem sklopu treninga, je prirojena sposobnost. Glavni faktor, na katerega učinkuje, je razmerje med počasnim in hitrim krčenjem mišičnih vlaken neke osebe. Počasno krčenje vlaken poskrbi za večjo vzdržljivost, hitro krčenje vlaken pa moč in velikost.

Poskusite doseči maksimalen mišični razvoj s postavitvijo drsnika %-POCASNEGA-KRCENJA-VLAKEN na 90% in nato na 10%. Kako se dobljeni rezultati spremenijo glede na prirojeno sposobnost? Metode treniranja? Kaj nam to pove o povprečnih ljudeh, ki sledijo rutini genetsko nadarjenih profesionalnih bodybuilderjev?

RAZŠIRITEV MODELA
-------------------
1. Da si zagotovite dosego maksimalenega mišičnega razvoja, dodajte ogrado z imenom "max-muscle" v prikaz "Misicna rast". Zdaj prilagodite proceduro DO-PLOTTING tako, da uporabite "max-muscle" ogrado za prikaz vsote MAX-SIZE vrednosti vseh mišičnih vlaken.

2. Kvaliteta prehrane lahko ima velik vpliv na rezultate dosežene s treningom. Prilagodite model tako, da bo dopuščal ta vpliv. Dodajte spremenljivko NUTRIENT v gnezdo MUSCLE-FIBER. V model dodajte drsnik KVALITETA-PREHRANE. Zdaj prilagodite proceduro GO tako, da bo klicala funkcijo OBTAIN-NUTRITION, ki prenese hranila v sosede. Nazdnje spremenimo procedure GROW tako, da lahko pri dodajanju v mišično vlakno uporabimo razpoložljiva hranila.

3. Resnično življenje ustvari veliko nestalnosi v povprečnem posameznikovem programu treninga moči. V model dodajte spremenljivo funkcijo, ki bo odražala te nestalnosti: naključno naj generira noči z manj spanca in dodatne dneve počitka med treningi. Dodajte stikalo ki bo uporabniku dopuščalo prižgati ali ugasniti sprmenljivo funkcijo. Dodajte še drsnik ki bo uporabniku dopuščal regulirati raven spremenljivosti. Kakšne učinke imajo te nestalnosti na razvoj mišičja?
 
BODITE POZORNI
----------------
Človeško telo je neverjetno kompleksen sistem. Da bi simulirali njegove delčke, ki nas zanimajo,  predpostavimo obnašanje drugih delčkov. To se kaže v težavnosti kodiranja spremenljivih parametrov, kot so hormonske meje in maksimalna velikost mišičnih vlaken. Te predpostavke nam omogočajo osredotočenost na razumevanje celotnih procesov mišičnega razvoja, brez obremenjujočih preobsežnih informacij.

NETLOGOVE ZNAČILNOSTI
-----------------
Zapomnite si, da je uporaba primitiva REPEAT in spremenljivke %-POCASNEGA-KRCENJA-VLAKEN v proceduri CREATE-MUSCLE-FIBERS za generiranje normalne razporeditve maksimalnih velikosti mišičnih vlaken, centrirana na srednji vpliv vrednosti %-POCASNEGA-KRCENJA-VLAKEN.

Bodite pozorni na uporabo funkcije LOG v procedurah, ki regulirajo hormonsko izpustitev in ravnovesje. To nam dopušča skrbnejše posnemanje naravnih teženj za vsako dodatno enoto biološke komponente z dopustno prilagodljivo spremembo iz sistema.

Bodite pozorni na uporabo primitiva RGB v proceduri REGULATE-HORMONES za barvanje sosedov, ki bazira na hormnski kvantiteti in skrbi za mehek vizualen prehod iz anaboličnega v katabolično stanje. 

ZASLUGE IN REFERENCE
----------------------
Prvotna izvedba: Scott Styles, za Center for Connected Learning and Computer-Based Modeling.

Za sklicevanje na ta model v akademskih publikacijah uporabite:  Wilensky, U. (2002).  NetLogo Muscle Development model.  http://ccl.northwestern.edu/netlogo/models/MuscleDevelopment.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

V drugih publikacijah uporabite:Copyright 2002 Uri Wilensky.  Vse pravice pridržane.  Za pogoje uporabe obiščite http://ccl.northwestern.edu/netlogo/models/MuscleDevelopment.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.1.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@