breed [ listje ]
breed [ dead-leaves ]
breed [ raindrops ]
breed [ sun ]

listje-own [ water-level
             sugar-level
             attachedness
             chlorophyll   ;; green
             carotene      ;; yellow
             anthocyanin ] ;; red
globals [ bottom-line evaporating-temp]

;; ---------------------------------------
;; setup
;; ---------------------------------------

to setup
    ca
    set bottom-line  (min-pycor + 1)
    set evaporating-temp 30

    ;; Create sky and grass
    ask patches [ set pcolor blue - 2 ]
    ask patches with [ pycor < ( min-pycor + 2)] [ set pcolor green ]

    ;; Create leaves
    create-listje stevilo-listov
    ask listje [  set chlorophyll 50 + random 50
                  set water-level 50 + random 50
                  set sugar-level random-normal zacetno-povprecje-sladkorja zacetni-standardni-odklon-sladkorja
                  set carotene random 100
                  change-color
                  set attachedness 100 + random 50
                  ;; using sqrt in the next command makes the turtles be
                  ;; evenly distributed; if we just said "fd random-float 10"
                  ;; there'd be more turtles at the center of the tree, which
                  ;; would look funny
                  fd sqrt random-float 100 ]

    ;; Create trunk and branches
    cct 1 [
      set pen-size 10
      set color brown
      pen-down
      setxy 0 min-pycor
      set heading min-pycor
      bk 6
      lt 45 fd 7 bk 7
      rt 90 fd 7 bk 7
      lt 45
      fd 5
      lt 45 fd 7 bk 7
      rt 90 fd 7 bk 7
      lt 45 fd 7
      die
    ]

    ;; Create the sun
    create-custom-sun 1
    [ set xcor (max-pxcor - 2)
      set ycor (max-pycor - 3)
      set shape "circle"
    ]
    show-intenziteta-sonca

    set-default-shape raindrops "circle"
end


;; ---------------------------------------
;; go
;; ---------------------------------------

to go
    ;; Stop if all of the leaves are dead
    if not any? listje [ stop ]

    ;; Let the weather do its thing
    ;; (No procedures are necessary for sun or temperature.)
    make-wind-blow
    make-rain-fall
    show-intenziteta-sonca

    ;; Now our leaves respond accordingly
    ask listje with [attachedness > 0 ]
    [
      adjust-water
      adjust-chlorophyll
      adjust-sugar
      change-color
    ]

    ask listje [ fall-if-necessary ]

    ;; Leaves on the bottom should be killed off
    ask listje with [ ycor <= bottom-line ]
      [ set breed dead-leaves ]

    ;; Leaves without water should also be killed off
    ask listje with [ water-level < 1 ]
      [ set attachedness 0 ]

    ;; Make sure that values remain between 0 - 100
    ask listje [
      if chlorophyll < 0 [ set chlorophyll 0 ]
      if chlorophyll > 100 [ set chlorophyll 100 ]

      if water-level < 0 [ set water-level 0 ]
      if water-level > 100 [ set water-level 100 ]

      if sugar-level < 0 [ set sugar-level 0 ]
      if sugar-level > 100 [ set sugar-level 100 ]

      if carotene < 0 [ set carotene 0 ]
      if carotene > 100 [ set carotene 100 ]

      if anthocyanin < 0 [ set anthocyanin 0 ]
      if anthocyanin > 100 [ set anthocyanin 100 ]

      if attachedness < 0 [ set attachedness 0 ]
      if attachedness > 100 [ set attachedness 100 ]
    ]

    ;; Make a plot of what's going on
    do-plot
end


;; ---------------------------------------
;; make-wind-blow: When the wind blows,
;; the leaves move around a little bit
;; (for a nice graphical effect), and
;; reduce their attachedness by the wind factor.  This
;; means that leaves will fall off more rapidly
;; in stronger winds.
;; ---------------------------------------

to make-wind-blow
  ask listje [ ifelse random 2 = 1
                 [ rt (10 * faktor-vetra) ]
                 [ lt (10 * faktor-vetra) ]
               set attachedness attachedness - faktor-vetra
             ]
end


;; ---------------------------------------
;; make-rain-fall: rain is a separate breed
;; of small turtles that come from the top of the view.
;; ---------------------------------------

to make-rain-fall

  ; Create new raindrops at the top of the screen
  create-custom-raindrops intenziteta-dezja [ setxy (random-float world-width) max-pycor
                                           set heading 180 + random 10
                                           fd 0.5 - random-float 1.0
                                           set size .3
                                           set color gray
                                         ]
  ; Existing raindrops should fall
  ask raindrops [ fd 1 ]

  ; raindrops disappear when they reach the bottom of the screen
  ask raindrops with [ycor < bottom-line] [ die ]
end


;; --------------------------------------------------------
;; show-sun-intensity: Change the color of the uppermost
;; patches to show the sun
;; --------------------------------------------------------

to show-intenziteta-sonca
  ask sun [ set color scale-color yellow intenziteta-sonca 0 150
            set size (intenziteta-sonca / 10)
            set label intenziteta-sonca + "%"
            if intenziteta-sonca < 50 [ set label-color yellow ]
            if intenziteta-sonca >= 50 [ set label-color black ]
           ]
end

;;---------------------------------------------------------
;; Turtle Procedures
;; --------------------------------------------------------

;; --------------------------------------------------------
;; adjust-water: Handle the ups and downs of water within the leaf
;; --------------------------------------------------------

to adjust-water

  ;; Below a certain temperature, the leaf does not absorb
  ;; water any more.  Instead, it converts sugar and and water
  ;; to anthocyanin, in a proportion
  if temperatura < 10 [ stop  ]

  ;; If there is a raindrop on this leaf, then absorb its water
  ;; (and reduce the attachedness by the rain's intensity)
  if any? raindrops-here
    [ set water-level (water-level + (2 * count raindrops-here))
      set attachedness (attachedness - (intenziteta-dezja / 10))
    ]

  ;; Reduce the water according to the temperature
  if temperatura > evaporating-temp
    [ set water-level (water-level - (temperatura - evaporating-temp)) ]

  ;; If the water level goes too low, reduce the attachedness
  if water-level < 25
    [ set attachedness (attachedness - 1) ]

end


;; ---------------------------------------
;; adjust-chlorophyll: It's not easy being green.
;; Chlorophyll gets reduces when the temperature is
;; low, or when the sun is strong.  It increases when
;; the temperature is normal and the sun is shining.
;; ---------------------------------------

to adjust-chlorophyll

  ;; If the temperature is low, then reduce the chlorophyll
  if temperatura < 15
    [ set chlorophyll (chlorophyll - (.5 * (15 - temperatura))) ]

  ;; If the sun is strong, then reduce the chlorophyll
  if intenziteta-sonca > 75
    [ set chlorophyll (chlorophyll - (.5 * (intenziteta-sonca - 75))) ]

  ;; New chlorophyll comes from water and sunlight
  if temperatura > 15 and intenziteta-sonca > 20
    [ set chlorophyll (chlorophyll + 1) ]

end


;; ---------------------------------------
;; adjust-sugar: water + sunlight + chlorophyll = sugar
;; ---------------------------------------

to adjust-sugar
  ;; If there is enough water and sunlight, reduce the chlorophyll
  ;; and water, and increase the sugar
  if water-level > 1 and intenziteta-sonca > 20 and chlorophyll > 1
    [ set water-level (water-level - 0.5)
      set chlorophyll (chlorophyll - 0.5)
      set sugar-level (sugar-level + 1)
      set attachedness attachedness + 5
    ]

  ;; Every tick of the clock, we reduce the sugar by 1
  set sugar-level (sugar-level - 0.5)
end

;; ---------------------------------------
;; fall-if-necessary:  If a leaf is above the bottom row, make it fall down
;; If it hits the bottom line, make it a dead-leaf
;; ---------------------------------------

to fall-if-necessary
  if attachedness > 0 [ stop ]

  if ycor > bottom-line
    [ let target-patch-xcor int (xcor + random-float faktor-vetra
                                      - random-float faktor-vetra)

      if target-patch-xcor < min-pxcor
        [ set target-patch-xcor min-pxcor ]

      if target-patch-xcor > max-pxcor
        [ set target-patch-xcor max-pxcor ]

      set heading towards-nowrap patch target-patch-xcor bottom-line

      fd random-float (.7 * max (list faktor-vetra .5))
      if ycor > (max-pycor - 3) [ set ycor min-pycor ]
     ]
end


;; ---------------------------------------
;; change-color: Because NetLogo has a limited color scheme,
;; we need very simple rules
;; ---------------------------------------

to change-color
  ;; If the temperature is low, then we turn the
  ;; sugar into anthocyanin
  if temperatura < 20 and sugar-level > 0 and water-level > 0
    [ set sugar-level (sugar-level - 1)
      set water-level (water-level - 1)
      set anthocyanin (anthocyanin + 1 ) ]

  ;; If we have more than 50 percent chlorophyll, then
  ;; we are green, and scale the color accordingly
  ifelse chlorophyll > 50
       [ set color scale-color green chlorophyll 150 -50 ]

  ;; If we are lower than 50 percent chlorophyll, then
  ;; we have yellow (according to the carotene), red (according
  ;; to the anthocyanin), or orange (if they are about equal).

       ;; If we have roughly equal anthocyanin and carotene,
       ;; then the leaves should be in orange.
       [ if abs (anthocyanin - carotene ) < 10
           [ set color scale-color orange carotene 150 -50 ]

         if anthocyanin > carotene + 10
           [ set color scale-color red anthocyanin 170 -50 ]

         if carotene > anthocyanin + 10
           [ set color scale-color yellow carotene 150 -50 ]
       ]
end


;; ---------------------------------------
;; Plotting Procedures
;; ---------------------------------------

;; ---------------------------------------
;; do-plot: Plot our measurements
;; ---------------------------------------

to do-plot
    ;; Plot info about the number of leaves
    set-current-plot "Listje"

    set-current-plot-pen "listje"
    plot count listje

    set-current-plot-pen "mrtvo listje"
    plot count dead-leaves

    ;; Plot info about weather conditions
    set-current-plot "Vremenski pogoji"

    set-current-plot-pen "temperatura"
    plot temperatura

    set-current-plot-pen "sonce"
    plot intenziteta-sonca

    set-current-plot-pen "dez"
    plot intenziteta-dezja

    set-current-plot-pen "veter"
    plot faktor-vetra

    ;; Plot info about leaves
    if any? listje [

     set-current-plot "Povprečja nihanja v listih"

     set-current-plot-pen "voda"
     plot mean values-from listje [ water-level ]

     set-current-plot-pen "klorofil"
     plot mean values-from listje [ chlorophyll ]

     set-current-plot-pen "sladkor"
     plot mean values-from listje [ sugar-level ]

     set-current-plot-pen "karoten"
     plot mean values-from listje [ carotene ]

     set-current-plot-pen "anticianin"
     plot mean values-from listje [ anthocyanin ]

     set-current-plot-pen "pritrjenost"
     plot mean values-from listje [ attachedness ]
    ]
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS and INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) -- grant numbers
; REC #9814682 and REC-0126227.
;
; Copyright 2005 by Uri Wilensky.  Updated 2005.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2005).  NetLogo Autumn model.
; http://ccl.northwestern.edu/netlogo/models/Autumn.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 2005 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/Autumn
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
356
10
716
391
17
17
10.0
1
12
1
1
1
0
1
1
1
-17
17
-17
17

CC-WINDOW
5
551
725
646
Command Center
0

SLIDER
10
10
226
43
stevilo-listov
stevilo-listov
0
2500
1269
1
1
NIL

BUTTON
41
117
149
150
NASTAVITVE
setup
NIL
1
T
OBSERVER
T
NIL

SLIDER
431
469
628
502
faktor-vetra
faktor-vetra
0
10
1
1
1
NIL

BUTTON
149
117
226
150
NAPREJ
go
T
1
T
OBSERVER
T
NIL

SLIDER
431
401
629
434
temperatura
temperatura
0.0
40.0
12.0
1.0
1
stopinj C

SLIDER
431
435
628
468
intenziteta-dezja
intenziteta-dezja
0
15
2
1
1
NIL

SLIDER
431
503
628
536
intenziteta-sonca
intenziteta-sonca
0
100
60
1
1
%

PLOT
13
157
345
278
Listje
Cas
NIL
0.0
10.0
0.0
100.0
true
true
PENS
"listje" 1.0 0 -10899396 true
"mrtvo listje" 1.0 0 -6459832 true

PLOT
13
282
345
402
Vremenski pogoji
Cas
NIL
0.0
10.0
0.0
10.0
true
true
PENS
"temperatura" 1.0 0 -2674135 true
"dez" 1.0 0 -13345367 true
"veter" 1.0 0 -16777216 true
"sonce" 1.0 0 -1184463 true

PLOT
13
405
345
537
Povprečja nihanja v listih
Cas
NIL
0.0
10.0
0.0
10.0
true
true
PENS
"klorofil" 1.0 0 -10899396 true
"voda" 1.0 0 -13345367 true
"sladkor" 1.0 0 -7500403 true
"karoten" 1.0 0 -1184463 true
"anticianin" 1.0 0 -2674135 true
"pritrjenost" 1.0 0 -16777216 true

SLIDER
11
45
253
78
zacetno-povprecje-sladkorja
zacetno-povprecje-sladkorja
0.0
100.0
65.0
1.0
1
NIL

SLIDER
11
79
262
112
zacetni-standardni-odklon-sladkorja
zacetni-standardni-odklon-sladkorja
0.0
50.0
24.0
1.0
1
NIL

@#$#@#$#@
KAJ JE?
-----------
Če živiš v takšnem klimatskem območju, kjer je poleti toplo in pozimi hladno, potem 
si verjetno seznanjen z lepotami jesenskega pojava, ko se listje obarva, še predno
odmre in pade z drevesa. Ta model prikazuje različne poti, kako listje spreminja barvo
in nam omogoča raziskati in razumeti ta lep letni spektakel.

KAKO DELUJE?
------------
Zakaj in kako listje spreminja svojo barvo preden odpade, je zapleten proces in je odvisen od kombinacije sončne svetlobe, vročine in dežja. Očitno je, da lahko listje pri močnem vetru odpade z drevesa, čeprav se še ni obarvalo. To pomeni, da veter in močan dež igrata pomembno vlogo pri odpadanju listja.

Barve, ki jih mi vidimo, izvirajo iz različnih lastnosti, ki so individualne za vsak list posebej:

- Zeleno barvo daje klorofil ali vrsta pigmenta poznanega kot klorofil. Ta pretvarja sončno svetlobo in vodo v sladkor. Klorofil razpade, ko je izpostavljen prekomerni količini sončne svetlobe ali kadar so nizke temperature. Sončni in hladni dnevi povzročijo, da klorofil še posebej hitro izgine. Količina klorofila v listih se poveča, kadar je dovolj sončne svetlobe, vendar ne preveč in kadar je dovolj vode.

- Rumeno barvo daje karoten, podobno kot korenčku in sladkemu krompirju in ostane stalno skozi vse življenje lista. Kakorkoli, rumena barva je pogosto prikrita z zeleno barvo klorofila. Litje z veliko klorofila bo pretežno zeleno, čeprav se bo v ozadju zelene barve skrivala močna rumena barva. Ta bo prišla v ospredje, ko bo klorofil razpadel.

- Rdečo barvo daje anticianin, ki je rezultat visoke koncentracije sladkorja v listih.Večja kot je koncentracija sladkorja, več anticianina se proizvede.
Koncentracija sladkorja se poveča, kadar hladno vreme ustavi oskrbo drevesa z vodo. 
Voda in sladkor, ki sta ostala ujeta v liste, ko se je odvijala ta prekinitev dotoka vode, sta se spremenila v anticianin.

Časovni interval je sestavljen iz dveh stopenj: (1) vreme (dež,veter,sonce) vpliva na listje, dodaja ali odstranjuje sladkor, vodo, ali klorofil kot je primerno in (2) listje vpliva na svoje okolje z dodajanjem anticianina kot je primerno, in odraža spremenjeno okolje s spreminjanjem barve.

Tukaj je tudi dodatna želvja spremenljivka "pritrjenost", katero model uporablja zato, da pokaže, kako močno se listje drži drevesa. Pritrjenost listov narašča z vodo in pojema z vetrom in dežjem. Tako lahko vetroven dan povzroči, da odpade z drevesa popolnoma zeleno listje. To pa je preprosto zato, ker je vsak faktor pritrjenosti listja zmanjšan z vsakim časovnim intervalom.

Ker Netlogo ne daje možnosti mešanja barv, uporablja ta model začetni algoritem. Vsakič ko je količina klorofila nad 50%, je listje zeleno. Pod tem listje dobi rumeno, rdečo ali oranžno barvo, odvisno od tega, če prevladuje v listju karoten, anticianin ali oba, vsak zase.

Upoštevaj, da se intenziteta barve listja spreminja s stopnjo klorofila, karotena, in/ali anticianina. Tako bo drevo z veliko klorofila imelo temno zelene liste, medtem ko bo imelo tisto z malo klorofila svetlo zelene liste.

KAKO GA UPORABLJATI?
-------------
Če želiš uporabljati model, najprej pritisni na gumb NASTAVITVE. To bo povzročilo ustvarjanje drevesnega debla, korenin in prav tako listja, ki je najpomembnejši predstavnik v tem modelu. Nato pritisni na gumb NAPREJ, ki povzroči, da se sistem požene.

Sedaj pride na vrsto zanimiv in zapleteni del, imenovan nastavljanje drsnikov, pri katerem z nastavitvijo vremena proizvajamo pogoje, ki jih želimo imeti. Če se pokaže, da listje izgublja klorofil zaradi pomanjkanja vode, kar lahko kontroliraš v grafikonu Povprečja nihanja v listih, lahko količino dežja nastavljaš z ustreznim drsnikom, kjer piše intenziteta-dezja. Sunek vetra pa kontroliraš z drsnikom, kjer piše faktor-vetra.

Moč sonca, dokler je vsebovana sončna svetloba, nastaljamo z drsnikom, kjer piše intenziteta-sonca. Kot smo že omenili, listje potrebuje sončno svetlobo, da proizvaja klorofil in sladkor. Toda preveč sončne svetlobe lahko začne uničevati te kemikalije.

Končno lahko spreminjaš tudi drsnik temperatura, s katerim nastavljaš temperaturo, ki lahko uniči klorofil, če je prehladno, in povzročiš ustvarjanja anticianina.

Enkrat, ko boste že obvladali osnove modela, boste mogoče hoteli preučiti nastavitve dveh drsnikov, ki se nahajajo na vrhu v levem kotu, ZACETNO-POVPRECJE-SLADKORJA in ZACETNI-STANDARDNI-ODKLON-SLADKORJA, ki vplivata na povprečje in obseg začetne razporeditve sladkorja v listih. Na primer: javorjevi listi so nagnjeni k temu, da imajo že na začetku veliko sladkorja v listih, kar pomeni, da se bodo obarvali bolj rdeče kot drugi listi pri podobnih pogojih.


STVARI, KI JIH JE TREBA PRIPOMNITI
----------------
Listje vsrkava vodo, kadar nanj padajo dežne kaplje, kar pomeni, da pri veliko listih, na katere rahlo dežuje, na notranje liste ne pade dovolj dežja.

Močnejši kot je veter, bolj se vsak list trese.

Če nastaviš vrednosti za intenziteto vetra in dežja na njun maksimum, lahko simuliraš manjši orkan. Glej, kako vse listje naenkrat odpade.

STVARI, KI JIH LAHKO POSKUSIŠ
-------------
Ali lahko narediš tako, da se vse listje obarva rdeče, še preden odpade? Kaj pa oranžno, še predno odpade? Ali pa rumeno? Sedaj poskusi stvari pomešati tako, da boš dobil listje različnih barv. Namig: verjetno boš moral za pravo kombinacijo večkrat nastavljati drsnike za sonce, dež in temperaturo.

Poskusi narediti, da se listje obarva najprej rumeno in potem nazaj zeleno.

Kot veš, v nekaterih klimatskih območjih drevesa ne izgubijo svojih listov. Ali lahko ustvariš takšne pogoje, da bo nekaj listov ostalo na drevesu?

RAZŠIRITEV MODELA
-------------------

V resničnem svetu se listje, ki gleda proti soncu, nagiba k temu, da je bolj rumeno, kot tisto, ki se ne. Spremeni model tako, da lahko sonce namestiš in odstraniš. Listi, ki gledajo proti soncu, pa naj bodo bolj občutljivi na sončno svetlobo, kot tisti, ki ne.

Model je zelo enostaven in je le približek, kar se tiče vode namreč, saj vsa vodo pride iz dežja, deževne kaplje vplivajo na mnogovrstno listje in deževne kaplje izginejo, ko udarijo ob zemljo. Bolj realističen model bo imel takšne dežne kaplje, ki izginejo takoj, ko zadanejo ob list. Bo pa tudi dovolil, da voda pripotuje iz zemlje, skozi deblo in veje, do listov. 

Dovoli brstenje in rast novih listov, v zameno za odmiranje zrelih listov.

Dodaj dnevno-nočni ciklus, v katerem temperature padajo in sonce zaide za nekaj časa.

NETLOGO-ove POSEBNOSTI
----------------

Ker Netlogo-ov barvni model trenutno ne omogoča nobenega načina mešanja barv, je bilo potrebno stvari malo improvizirati. Upoštevaj, kako smo obravnavali nastavljanje barv s pomočjo začetka. To pomeni, da lahko pri malo bolj ekstremnih vremenskih pogojih, dobimo nepričakovano, neskladno barvo. 

Prav tako upoštevaj, da Netlogo-ova barvna shema in osnovna barvna lestvica, ustvarijo barve v obsegu od bele do črne. Ker ta model želi spreminjati barvne odtenke, ne da bi prišel preblizu črne ali bele barve, uporablja osnovno barvno lestvico v obsegu -50-150 in ne običajne lestvice, ki je v obsegu 0-100.

Ko listje odmre, se njegovo potomstvo spremeni v mrtve liste. To jih obdrži v sistemu. Navodila pa nam dovoli dajati le listom, ki so živi.

Opazuj, kako se spreminja barva listov, če spreminjamo intenziteto sonca. Kaj se zgodi na grafikonu, ko sonce potemni in postane malo?

ZASLUGE IN VIRI
----------------------
http://scifun.chem.wisc.edu/chemweek/fallcolr/fallcolr.html
http://www.the-scientist.com/yr2001/dec/palevitz_p8_011210.html

Pri sklicevanju na ta model v visokošolskih publikacijah, prosim uporabite:
Wilensky, U. (2005). NetLogo Autumn model. http://ccl.northwestern.edu/netlogo/models/Autumn. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

V ostalih publikacijah prosim uporabite:
Copyright 2005 Uri Wilensky. All rights reserved. 
Glejte http://ccl.northwestern.edu/netlogo/models/Autumn za termine uporabe. 
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.1.2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@