Predvajalnik video posnetkov (datotek AVI)

to avifile
   windowcreate "root "okno [Predvajalnik video posnetkov (datotek AVI)] 0 0 220 60 []
   groupboxcreate "okno "g1 5 3 208 20
   staticcreate "okno "s1 [Datoteka:] 10 11 30 10
   staticcreate "okno "s2 [] 45 11 160 10
   buttoncreate "okno "b1 [Izberi datoteko] 15 30 60 12 [izberi]
   buttoncreate "okno "b2 [Začni] 80 30 60 12 [startstop]
   buttoncreate "okno "b3 [Končaj] 145 30 60 12 [končaj]
   make "datoteka []
   make "igram "false
end

to izberi
   local "temp
   make "temp dialogfileopen "c:\\*.avi
   if not emptyp :temp [
      make "datoteka :temp
      staticupdate "s2 first :datoteka
   ]
end

to startstop
   ifelse :igram [avistop] [
      if emptyp :datoteka [messagebox "Napaka [Najprej izberi datoteko!] stop]
      buttonupdate "b2 [Ustavi]
      zaigrajAVI first :datoteka
   ]
end

to zaigrajAVI :datoteka
   show mci (sentence [open] :datoteka [type avivideo alias video])
   make "igram "true
   (mci [play video notify] [avistop])
end

to avistop
   if :igram [
      mci [stop video wait]
      mci [close video wait]
      make "igram "false
      buttonupdate "b2 [Začni]
   ]
end

to končaj
   avistop
   windowdelete "okno
end